Unless marked otherwise, all macros have been tested with QLab 4.4.1 in Mac OS X 10.12.6.

Macros that are useful to keep on a hotkey so they can act on selected cues, or in the current location – or will be needed often.

Bump the Master on the Levels tab of the selected Audio, Mic, Video or Fade Cue(s) -2.5dB (it should be obvious how to adjust that number):

/cue/selected/level/0/0/- 2.5

Set crosspoints of selected Audio, Mic or Video Cue(s) for mono routing (crosspoints will be set at 0dB for mono files and -6dB for stereo files):

-- Best run as a separate process so it can be happening in the background, as it is quite slow
 
set qLabMaxAudioChannels to 64
 
tell application id "com.figure53.QLab.4" to tell front workspace
	repeat with eachCue in (selected as list)
		try
			if audio input channels of eachCue is 1 then
				repeat with i from 1 to qLabMaxAudioChannels
					setLevel eachCue row 1 column i db 0
				end repeat
			else if audio input channels of eachCue is 2 then
				repeat with i from 1 to qLabMaxAudioChannels
					setLevel eachCue row 1 column i db -6
					setLevel eachCue row 2 column i db -6
				end repeat
			end if
		end try
	end repeat
end tell

Add 1s to the Pre Wait of the selected cue(s):

/cue/selected/preWait/+ 1

Add 1s to the Duration of the selected cue(s):

/cue/selected/duration/+ 1

Add 1s to the Post Wait of the selected cue(s):

/cue/selected/postWait/+ 1

Set Post Wait(s) of selected Group Cue(s) to effective duration (for those times when a countdown display is useful…); the functionality of this script is now built into QLab for “Timeline” Group Cues:

-- The effective duration of a Group Cue is the time it will take for the longest of its children to complete, ie: the longest effective duration of one of its children
-- Each child cue has an effective Pre Wait, which is the cumulative time that must elapse before this child's Pre Wait is triggered
-- In a "Start first child and go to next cue" Group Cue this effective Pre Wait is the sum of all the Pre Waits and Post Waits that have come before
-- Note that auto-follow cues use their Durations as Post Waits (the actual Post Wait property is ignored); this is the value that must be added to the sum above
-- The effective duration of a single cue that does not auto-follow is the sum of its effective Pre Wait and the longer of its Duration or Post Wait
-- The effective duration of a single cue that does auto-follow is the sum of its effective Pre Wait & Duration
 
tell front workspace
	repeat with eachCue in (selected as list)
		try
			set eachMode to mode of eachCue
			set longestChildEffectiveDuration to 0
			if eachMode is fire_first_go_to_next_cue then
				set effectivePreWait to 0
				repeat with eachChild in cues of eachCue
					set eachPre to pre wait of eachChild
					set effectivePreWait to effectivePreWait + eachPre
					set eachContinueMode to continue mode of eachChild
					if eachContinueMode is auto_follow then
						set eachPost to duration of eachChild
						set eachChildEffectiveDuration to effectivePreWait + eachPost
					else
						set eachDuration to duration of eachChild
						set eachPost to post wait of eachChild
						if eachPost > eachDuration then
							set eachChildEffectiveDuration to effectivePreWait + eachPost
						else
							set eachChildEffectiveDuration to effectivePreWait + eachDuration
						end if
					end if
					set effectivePreWait to effectivePreWait + eachPost
					if eachChildEffectiveDuration > longestChildEffectiveDuration then
						set longestChildEffectiveDuration to eachChildEffectiveDuration
					end if
					if eachContinueMode is do_not_continue then
						exit repeat -- No point looking at any further children that aren't part of the sequence
					end if
				end repeat
			end if
			set post wait of eachCue to longestChildEffectiveDuration
		end try
	end repeat
end tell

Create a 5s default fade in of the selected Audio, Mic or Video Cue as the next cue in the cue list (also set the Master on the Levels tab of the selected cue to -INF and copy the Pre Wait time from the selected cue – for use in a “Timeline” Group Cue):

set userDuration to 5
set userMinVolume to -120 -- Set what level you mean by "faded out" (you can adjust this to match the workspace "Min Volume Limit" if necessary)
 
tell front workspace
	try -- This protects against no selection (can't get last item of (selected as list))
		set originalCue to last item of (selected as list)
		if q type of originalCue is in {"Audio", "Mic", "Video"} then
			set originalCueLevel to originalCue getLevel row 0 column 0
			originalCue setLevel row 0 column 0 db userMinVolume
			set originalPreWait to pre wait of originalCue
			make type "Fade"
			set newCue to last item of (selected as list)
			set cue target of newCue to originalCue
			set pre wait of newCue to originalPreWait
			set duration of newCue to userDuration
			newCue setLevel row 0 column 0 db originalCueLevel
			set q name of newCue to "Fade in: " & q list name of originalCue
		end if
	end try
end tell

Create a 5s default fade in of the selected Audio, Mic or Video Cue as the next cue in the cue list (also set the Master on the Levels tab of the selected cue to -INF and create a follow-on); doesn't fire in a cart:

set userDuration to 5
set userMinVolume to -120 -- Set what level you mean by "faded out" (you can adjust this to match the workspace "Min Volume Limit" if necessary)
 
tell front workspace
	if q type of current cue list is "Cart" then return -- This will stop the script if we're in a cart, as it doesn't make sense to continue!
	try -- This protects against no selection (can't get last item of (selected as list))
		set originalCue to last item of (selected as list)
		if q type of originalCue is in {"Audio", "Mic", "Video"} then
			set originalCueLevel to originalCue getLevel row 0 column 0
			originalCue setLevel row 0 column 0 db userMinVolume
			set continue mode of originalCue to auto_continue
			make type "Fade"
			set newCue to last item of (selected as list)
			set cue target of newCue to originalCue
			set duration of newCue to userDuration
			newCue setLevel row 0 column 0 db originalCueLevel
			set q name of newCue to "Fade in: " & q list name of originalCue
		end if
	end try
end tell

Create a 5s default fade out (and stop) of the selected Group, Audio, Mic or Video Cue (or target of selected Fade Cue) as the next cue in the cue list (the script does not stop (targeted) Video Cues):

set userDuration to 5
set userMinVolume to -120 -- Set what level you mean by "faded out" (you can adjust this to match the workspace "Min Volume Limit" if necessary)
 
tell front workspace
	try -- This protects against no selection (can't get last item of (selected as list))
		set originalCue to last item of (selected as list)
		set originalCueType to q type of originalCue
		if originalCueType is in {"Group", "Audio", "Mic", "Video"} then
			make type "Fade"
			set newCue to last item of (selected as list)
			set cue target of newCue to originalCue
			set duration of newCue to userDuration
			newCue setLevel row 0 column 0 db userMinVolume
			if originalCueType is not "Video" then
				set stop target when done of newCue to true
			end if
			set q name of newCue to "Fade out: " & q list name of originalCue
		else if originalCueType is "Fade" then
			set originalCueTarget to cue target of originalCue
			make type "Fade"
			set newCue to last item of (selected as list)
			set cue target of newCue to originalCueTarget
			set duration of newCue to userDuration
			newCue setLevel row 0 column 0 db userMinVolume
			if q type of originalCueTarget is not "Video" then
				set stop target when done of newCue to true
			end if
			set q name of newCue to "Fade out: " & q list name of originalCueTarget
		end if
	end try
end tell

Create a 5s default fade of the selected Group, Audio, Mic or Video Cue (or target of selected Fade Cue) as the next cue in the cue list, building the Master +5dB (the script does nothing if the selected Fade Cue targets a Group Cue):

set userDuration to 5
set userLevel to 5
set userKindString to "Build: "
 
tell front workspace
	try -- This protects against no selection (can't get last item of (selected as list))
		set originalCue to last item of (selected as list)
		set originalCueType to q type of originalCue
		if originalCueType is "Group" then
			make type "Fade"
			set newCue to last item of (selected as list)
			set cue target of newCue to originalCue
			set duration of newCue to userDuration
			newCue setLevel row 0 column 0 db userLevel
			set q name of newCue to userKindString & q list name of originalCue
		else if originalCueType is in {"Audio", "Mic", "Video"} then
			make type "Fade"
			set newCue to last item of (selected as list)
			set cue target of newCue to originalCue
			set duration of newCue to userDuration
			set currentLevel to originalCue getLevel row 0 column 0
			newCue setLevel row 0 column 0 db (currentLevel + userLevel)
			set q name of newCue to userKindString & q list name of originalCue
		else if originalCueType is "Fade" then
			set originalCueTarget to cue target of originalCue
			if q type of originalCueTarget is not "Group" then
				make type "Fade"
				set newCue to last item of (selected as list)
				set cue target of newCue to originalCueTarget
				set duration of newCue to userDuration
				set currentLevel to originalCue getLevel row 0 column 0
				newCue setLevel row 0 column 0 db (currentLevel + userLevel)
				set q name of newCue to userKindString & q list name of originalCueTarget
			end if
		end if
	end try
end tell

Create a 5s default fade of the selected Group, Audio, Mic or Video Cue (or target of selected Fade Cue) as the next cue in the cue list, dipping the Master -5dB (the script does nothing if the selected Fade Cue targets a Group Cue):

set userDuration to 5
set userLevel to -5
set userKindString to "Dip: "
 
tell front workspace
	try -- This protects against no selection (can't get last item of (selected as list))
		set originalCue to last item of (selected as list)
		set originalCueType to q type of originalCue
		if originalCueType is "Group" then
			make type "Fade"
			set newCue to last item of (selected as list)
			set cue target of newCue to originalCue
			set duration of newCue to userDuration
			newCue setLevel row 0 column 0 db userLevel
			set q name of newCue to userKindString & q list name of originalCue
		else if originalCueType is in {"Audio", "Mic", "Video"} then
			make type "Fade"
			set newCue to last item of (selected as list)
			set cue target of newCue to originalCue
			set duration of newCue to userDuration
			set currentLevel to originalCue getLevel row 0 column 0
			newCue setLevel row 0 column 0 db (currentLevel + userLevel)
			set q name of newCue to userKindString & q list name of originalCue
		else if originalCueType is "Fade" then
			set originalCueTarget to cue target of originalCue
			if q type of originalCueTarget is not "Group" then
				make type "Fade"
				set newCue to last item of (selected as list)
				set cue target of newCue to originalCueTarget
				set duration of newCue to userDuration
				set currentLevel to originalCue getLevel row 0 column 0
				newCue setLevel row 0 column 0 db (currentLevel + userLevel)
				set q name of newCue to userKindString & q list name of originalCueTarget
			end if
		end if
	end try
end tell

Force selected Fade Cue(s) to completion (the script will also optionally act on Fade Cues within selected Group Cues):

set userDuration to 1 -- This is the time the fade(s) will be forced to complete in
set userEnterIntoGroups to true -- Set this to false if you don't want the script to act on Fade Cues within selected Group Cues
 
tell front workspace
	set cuesToProcess to (selected as list)
	set processedIDs to {}
	set fadeCues to {}
	set originalPreWaits to {}
	set originalDurations to {}
	set originalContinueModes to {}
	set i to 0
	repeat until i = (count cuesToProcess) -- Extract just the Fade Cues
		set eachCue to item (i + 1) of cuesToProcess
		set eachType to q type of eachCue
		if eachType is "Fade" then
			set eachID to uniqueID of eachCue
			if eachID is not in processedIDs then
				set end of fadeCues to eachCue
				set end of processedIDs to eachID
			end if
		else if userEnterIntoGroups is true and eachType is "Group" then
			set cuesToProcess to cuesToProcess & cues of eachCue
		end if
		set i to i + 1
	end repeat
	repeat with eachCue in fadeCues
		stop eachCue
		set end of originalPreWaits to pre wait of eachCue
		set end of originalDurations to duration of eachCue
		set end of originalContinueModes to continue mode of eachCue
		set pre wait of eachCue to 0
		set duration of eachCue to userDuration
		set continue mode of eachCue to do_not_continue
		start eachCue
	end repeat
	delay userDuration + 0.1 -- Give the cue(s) time to complete before resetting to the original variables
	repeat with i from 1 to count fadeCues
		set eachCue to item i of fadeCues
		stop eachCue -- In case of Post Wait…
		set pre wait of eachCue to item i of originalPreWaits
		set duration of eachCue to item i of originalDurations
		set continue mode of eachCue to item i of originalContinueModes
	end repeat
end tell

Force running Fade Cue(s) to completion:

set userDuration to 1 -- This is the time the fade(s) will be forced to complete in
 
tell front workspace
	set fadeCues to {}
	set originalPreWaits to {}
	set originalDurations to {}
	set originalContinueModes to {}
	repeat with eachCue in (active cues as list) -- Extract just the Fade Cues
		if q type of eachCue is "Fade" then
			set end of fadeCues to eachCue
		end if
	end repeat
	repeat with eachCue in fadeCues
		stop eachCue
		set end of originalPreWaits to pre wait of eachCue
		set end of originalDurations to duration of eachCue
		set end of originalContinueModes to continue mode of eachCue
		set pre wait of eachCue to 0
		set duration of eachCue to userDuration
		set continue mode of eachCue to do_not_continue
		start eachCue
	end repeat
	delay userDuration + 0.1 -- Give the cue(s) time to complete before resetting to the original variables
	repeat with i from 1 to count fadeCues
		set eachCue to item i of fadeCues
		stop eachCue -- In case of Post Wait…
		set pre wait of eachCue to item i of originalPreWaits
		set duration of eachCue to item i of originalDurations
		set continue mode of eachCue to item i of originalContinueModes
	end repeat
end tell

Crash selected Fade Cue(s) to just before completion, starting their target cues (the script will start the target cue(s) for the selected Fade Cue(s), load the Fade Cue(s) to just before completion and start them):

set userDuration to 1 -- This is the time remaining to which to load the Fade Cue(s) before starting them
 
tell front workspace
	repeat with eachCue in (selected as list)
		if q type of eachCue is "Fade" then
			set eachCueTarget to cue target of eachCue
			if running of eachCueTarget is false then
				load eachCueTarget time pre wait of eachCueTarget
				start eachCueTarget
			end if
			stop eachCue -- In case the Fade Cue is a follow-on from its target
			set eachDuration to ((pre wait of eachCue) + (duration of eachCue)) -- Include the Pre Wait for effective duration!
			if eachDuration > userDuration then
				load eachCue time eachDuration - userDuration
			end if
			start eachCue
		end if
	end repeat
end tell

Prepare selected Fade Cue(s) for preview by starting their target cues:

tell front workspace
	repeat with eachCue in (selected as list)
		if q type of eachCue is "Fade" then
			set eachCueTarget to cue target of eachCue
			if running of eachCueTarget is false then
				preview eachCueTarget
			end if
		end if
	end repeat
end tell

Turn on infinite loop in selected Audio or Video Cue(s):

/cue/selected/infiniteLoop 1

Set last slice of selected Audio or Video Cue(s) to loop:

/cue/selected/lastSliceInfiniteLoop 1

Set playback rate of selected Audio, Video or Fade Cue(s) (also acts on MIDI File Cues); this functionality is now built-in too:

set userDefaultToVarispeed to true -- Change this to false if you prefer to default to no pitch shift
 
-- Declarations
 
global dialogTitle
set dialogTitle to "Set playback rate"
 
-- Main routine
 
if userDefaultToVarispeed is true then
	set customButtons to {"Cancel", "No pitch shift", "Varispeed"}
else
	set customButtons to {"Cancel", "Varispeed", "No pitch shift"}
end if
 
set {theRate, theOption} to enterANumberWithCustomButtons("Enter the playback rate:", "", customButtons, 3, 1)
 
tell front workspace
	repeat with eachCue in (selected as list)
		try
			set rate of eachCue to theRate
			if theOption is "Varispeed" then
				set pitch shift of eachCue to enabled
			else
				set pitch shift of eachCue to disabled
			end if
		end try
	end repeat
end tell
 
-- Subroutines
 
(* === INPUT === *)
 
on enterANumberWithCustomButtons(thePrompt, defaultAnswer, theButtons, defaultButton, cancelButton) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		set theQuestion to ""
		repeat until theQuestion is not ""
			set {theQuestion, theButton} to {text returned, button returned} of (display dialog thePrompt with title dialogTitle ¬
				default answer defaultAnswer buttons theButtons default button defaultButton cancel button cancelButton)
			try
				set theAnswer to theQuestion as number
			on error
				set theQuestion to ""
			end try
		end repeat
		return {theAnswer, theButton}
	end tell
end enterANumberWithCustomButtons

Change selected Audio Cue's target (keeping start/end times); it will also keep the cue's name, if it has been changed from the default:

-- QLab retains slice points within the duration of a new File Target but resets the start & end times (this script maintains start & end times)
 
tell front workspace
	try -- This protects against no selection (can't get last item of (selected as list))
		set selectedCue to last item of (selected as list)
		if q type of selectedCue is "Audio" then
			set currentStart to start time of selectedCue
			set currentEnd to end time of selectedCue
			set currentFileTarget to file target of selectedCue
			if currentFileTarget is not missing value then
				tell application "System Events"
					set whereToLook to (path of container of (currentFileTarget as alias)) as alias
				end tell
				set newFileTarget to choose file of type "public.audio" with prompt "Please select the new File Target:" default location whereToLook
			else
				set newFileTarget to choose file of type "public.audio" with prompt "Please select the new File Target:"
			end if
			set file target of selectedCue to newFileTarget
			set start time of selectedCue to currentStart
			set end time of selectedCue to currentEnd
		end if
	end try
end tell

Convert selected Audio Cue's target to wav, if it isn't one already (using the “afconvert” command line utility: can be modified to convert to aiff instead; the script keeps start & end times but resets the cue's name to default; bit depth and sample rate are user-defined within the script):

-- QLab retains slice points within the duration of a new File Target but resets the start & end times (this script maintains start & end times)
 
set userFormat to item 1 of {"wav", "aif"} -- Change this to "item 2" to convert to aiff
set userBitDepth to 16
set userBitRate to 44100
 
-- Declarations
 
global dialogTitle
set dialogTitle to "Convert to " & userFormat
 
-- Prepare some variables
 
if userFormat is "wav" then
	set acceptableTypes to {"com.microsoft.waveform-audio"}
	set formatString to "WAVE -d LEI"
else if userFormat is "aif" then
	set acceptableTypes to {"public.aifc-audio", "public.aiff-audio"}
	set formatString to "AIFF -d BEI"
else
	return -- Protection against erroneous user modification
end if
 
-- Convert the cue
 
tell front workspace
	try -- This protects against no selection (can't get last item of (selected as list))
		set selectedCue to last item of (selected as list)
		if q type of selectedCue is "Audio" then
			set currentFileTarget to file target of selectedCue as alias
			tell application "System Events"
				set currentType to type identifier of currentFileTarget
			end tell
			if currentType is not in acceptableTypes then
				set currentStart to start time of selectedCue
				set currentEnd to end time of selectedCue
				tell application "System Events"
					set theContainer to path of container of currentFileTarget
					set theExtension to name extension of currentFileTarget
					if theExtension is "" then
						set theName to name of currentFileTarget
					else
						set theFullName to name of currentFileTarget
						set theName to text 1 through (-1 - ((length of theExtension) + 1)) of theFullName
					end if
					set newFileTarget to theContainer & theName & "." & userFormat
					set fileExists to exists file newFileTarget
				end tell
				if fileExists is true then
					display dialog "The destination file for the conversion already exists. What now?" with title dialogTitle with icon 0 ¬
						buttons {"Cancel", "Replace"} default button "Replace" cancel button "Cancel"
				end if
				display dialog "Preparing to convert…" with title dialogTitle with icon 1 ¬
					buttons {"Cancel", "OK"} default button "OK" cancel button "Cancel" giving up after 3 -- You have 3s to change your mind
				tell me to do shell script "afconvert -f " & formatString & userBitDepth & "@" & userBitRate & " " & ¬
					quoted form of POSIX path of currentFileTarget & " " & quoted form of POSIX path of newFileTarget
				set file target of selectedCue to newFileTarget
				set start time of selectedCue to currentStart
				set end time of selectedCue to currentEnd
				set q name of selectedCue to "" -- Remove this line if you don't want to reset the cue name too
				display dialog "Done." with title dialogTitle with icon 1 buttons {"OK"} default button "OK" giving up after 5
			end if
		end if
	end try
end tell

Copy and paste the selected Audio Cue, setting the original to end at the cursor and the copy to start from there; it requires that UI scripting be allowed for QLab (Accessibility setting under Privacy in System Preferences):

-- Only works properly when run as a separate process!
 
tell application id "com.figure53.QLab.4" to tell front workspace
 
	try -- This protects against no selection (can't get last item of (selected as list))
 
		set selectedCue to last item of (selected as list)
 
		if q type of selectedCue is not "Audio" then error -- Need to escape the whole script
 
		set startTime to start time of selectedCue
		set endTime to end time of selectedCue
 
		set splitTime to startTime + ((percent action elapsed of selectedCue) * (duration of selectedCue)) * (rate of selectedCue)
		-- ###FIXME### As of 4.4.1, "action elapsed" reports differently between clicking in waveform and loading to time when rate ≠ 1
 
		if splitTime - startTime ≤ 1.0E-3 or endTime - splitTime ≤ 1.0E-3 then error -- No point splitting if within 1ms of top/tail
		-- "percent action elapsed" reports 99.999% not 100% when a cue is loaded to its end time, so 1ms is a limit imposed by this rounding error
 
		stop selectedCue -- Just to make it clearer what's going on
 
		-- Now, a slightly bodgy way of making sure that focus is not in the Inspector – so copy/paste works properly – and only one cue selected
 
		moveSelectionUp
		if last item of (selected as list) is not selectedCue then -- Selected cue was at the top of a cue list!
			moveSelectionDown
		end if
 
	on error
 
		return -- Don't go any further…
 
	end try
 
end tell
 
-- Use UI scripting to copy & paste (yuck!)
 
try
	tell application "System Events" to tell (first application process whose bundle identifier is "com.figure53.QLab.4")
		-- set frontmost to true -- ###TESTING### Need this line if testing from Script Editor!
		click menu item "Copy" of menu 1 of menu bar item "Edit" of menu bar 1
		click menu item "Paste" of menu 1 of menu bar item "Edit" of menu bar 1
	end tell
on error
	my displayAlert("UI scripting failed!", "You need to adjust your privacy settings to allow QLab to control your computer…", "critical", {"Cancel", "OK"}, 2, 1)
	tell application "System Preferences"
		activate
		reveal anchor "Privacy_Assistive" of pane id "com.apple.preference.security"
	end tell
	return
end try
 
-- Set the times
 
tell application id "com.figure53.QLab.4" to tell front workspace
	set copiedCue to last item of (selected as list)
	set end time of selectedCue to splitTime
	set start time of copiedCue to splitTime
end tell
 
-- Subroutines
 
(* === ERROR HANDLING === *)
 
on displayAlert(theWarning, theMessage, theIcon, theButtons, defaultButton, cancelButton) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		if cancelButton is "" then
			if theIcon is "critical" then -- Triangle with app icon
				display alert theWarning message theMessage as critical buttons theButtons ¬
					default button item defaultButton of theButtons
			else if theIcon is "informational" then -- App icon
				display alert theWarning message theMessage as informational buttons theButtons ¬
					default button item defaultButton of theButtons
			else if theIcon is "warning" then -- App icon
				display alert theWarning message theMessage as warning buttons theButtons ¬
					default button item defaultButton of theButtons
			end if
		else
			if theIcon is "critical" then
				display alert theWarning message theMessage as critical buttons theButtons ¬
					default button item defaultButton of theButtons cancel button item cancelButton of theButtons
			else if theIcon is "informational" then
				display alert theWarning message theMessage as informational buttons theButtons ¬
					default button item defaultButton of theButtons cancel button item cancelButton of theButtons
			else if theIcon is "warning" then
				display alert theWarning message theMessage as warning buttons theButtons ¬
					default button item defaultButton of theButtons cancel button item cancelButton of theButtons
			end if
		end if
	end tell
end displayAlert

Copy slice markers of selected Audio or Video Cue to the Clipboard as tab-delimited text:

set userHeaderRow to "Slice time" & tab & "Play count" -- Set this to false if you don't want a header
 
tell front workspace
	try -- This protects against no selection (can't get last item of (selected as list))
		set selectedCue to last item of (selected as list)
		set recordTable to my recordToDelimitedText(slice markers of selectedCue, tab, return)
		if userHeaderRow is not false then
			set recordTable to userHeaderRow & return & recordTable
		end if
		set the clipboard to recordTable as text
	end try
end tell
 
-- Subroutines
 
(* === TEXT WRANGLING === *)
 
on recordToDelimitedText(theRecord, theColumnDelimiter, theRowDelimiter) -- [Shared subroutine]
	set passedTIDs to AppleScript's text item delimiters
	set delimitedList to {}
	set AppleScript's text item delimiters to theColumnDelimiter
	repeat with eachItem in theRecord
		set end of delimitedList to (eachItem as list) as text
	end repeat
	set AppleScript's text item delimiters to theRowDelimiter
	set delimitedText to delimitedList as text
	set AppleScript's text item delimiters to passedTIDs
	return delimitedText
end recordToDelimitedText

Copy almost all the scriptable settings from the Time & Loops and Device & Levels tabs of the Inspector for the selected cue, and then apply them to every Audio Cue in the workspace that references the same file target; the script does not process the “integrated fade envelope toggle”, as it can't copy the fades themselves…

-- Best run as a separate process so it can be happening in the background
 
set userChannelCount to 64 -- Set how many outputs you are using (no point settings levels or gangs beyond this number)
set userLevels to true -- Set this to false if you don't want to update levels
set userGangs to true -- Set this to false if you don't want to update gangs
set userPatch to true -- Set this to false if you don't want to update the Audio Output Patch
set userTimes to true -- Set this to false if you don't want to update start/end times and loop settings
set userSlices to true -- Set this to false if you don't want to update the slice settings (including last slice play count)
set userRate to true -- Set this to false if you don't want to update rate & pitch shift settings
 
-- Declarations
 
global dialogTitle, startTime
set dialogTitle to "Update all instances"
 
-- Find the last Audio Cue in the selection and check it has a valid target, or give up
 
tell application id "com.figure53.QLab.4"
 
	tell front workspace
 
		try
			set selectedCue to last item of (selected as list)
		on error
			return -- No selection
		end try
 
		if q type of selectedCue is "Audio" then
			set theTarget to file target of selectedCue
		else
			return -- Not an Audio Cue
		end if
 
		if theTarget is missing value then
			display dialog "The selected Audio Cue does not have a valid target." with title dialogTitle with icon 0 ¬
				buttons {"OK"} default button "OK" giving up after 5
			return
		end if
 
		my startTheClock()
 
		-- Copy the general properties (get them all regardless as only getting the ones we need would take longer)
 
		set theID to uniqueID of selectedCue
		set thePatch to patch of selectedCue
		set theStart to start time of selectedCue
		set theEnd to end time of selectedCue
		set thePlayCount to play count of selectedCue
		set theInfiniteLoop to infinite loop of selectedCue
		set theLastSlicePlayCount to last slice play count of selectedCue
		set theLastSliceInfiniteLoop to last slice infinite loop of selectedCue
		set theSliceRecord to slice markers of selectedCue
		set theRate to rate of selectedCue
		set thePitchShift to pitch shift of selectedCue
		set howManyChannels to audio input channels of selectedCue
 
		-- Copy the levels
 
		if userLevels is true then
			set theLevels to {}
			repeat with i from 0 to howManyChannels
				repeat with j from 0 to userChannelCount
					set end of theLevels to getLevel selectedCue row i column j
				end repeat
			end repeat
			set theLevelsRef to a reference to theLevels
		end if
 
		-- Copy the gangs
 
		if userGangs is true then
			set theGangs to {}
			repeat with i from 0 to howManyChannels
				repeat with j from 0 to userChannelCount
					set end of theGangs to getGang selectedCue row i column j
				end repeat
			end repeat
			set theGangsRef to a reference to theGangs
		end if
 
		-- Find the other instances
 
		set allInstances to cues whose broken is false and q type is "Audio" and file target is theTarget and uniqueID is not theID
		set allInstancesRef to a reference to allInstances
		set countInstances to count allInstancesRef
 
		repeat with i from 1 to countInstances
 
			set eachCue to item i of allInstancesRef
 
			if userLevels is true then
				repeat with j from 0 to howManyChannels
					repeat with k from 0 to userChannelCount
						setLevel eachCue row j column k db (item (1 + j * (userChannelCount + 1) + k) of theLevelsRef)
					end repeat
				end repeat
			end if
 
			if userGangs is true then
				repeat with j from 0 to howManyChannels
					repeat with k from 0 to userChannelCount
						set storedValue to item (1 + j * (userChannelCount + 1) + k) of theGangsRef
						if storedValue is missing value then set storedValue to ""
						setGang eachCue row j column k gang storedValue
					end repeat
				end repeat
			end if
 
			if userPatch is true then
				set patch of eachCue to thePatch
			end if
 
			if userTimes is true then
				set start time of eachCue to theStart
				set end time of eachCue to theEnd
				set play count of eachCue to thePlayCount
				set infinite loop of eachCue to theInfiniteLoop
			end if
 
			if userSlices is true then
				set last slice play count of eachCue to theLastSlicePlayCount
				set last slice infinite loop of eachCue to theLastSliceInfiniteLoop
				set slice markers of eachCue to theSliceRecord
			end if
 
			if userRate is true then
				set rate of eachCue to theRate
				set pitch shift of eachCue to thePitchShift
			end if
 
			if i < countInstances then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countInstances, "instances")
			end if
 
		end repeat
 
		my finishedDialog()
 
	end tell
 
end tell
 
-- Subroutines
 
(* === OUTPUT === *)
 
on startTheClock() -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		display dialog "One moment caller…" with title dialogTitle with icon 1 buttons {"OK"} default button "OK" giving up after 1
	end tell
	set startTime to current date
end startTheClock
 
on countdownTimer(thisStep, totalSteps, whichCuesString) -- [Shared subroutine]
	set timeTaken to round (current date) - startTime rounding as taught in school
	set timeString to my makeMSS(timeTaken)
	tell application id "com.figure53.QLab.4"
		if frontmost then
			display dialog "Time elapsed: " & timeString & " – " & thisStep & " of " & totalSteps & " " & whichCuesString & ¬
				" done…" with title dialogTitle with icon 1 buttons {"Cancel", "OK"} default button "OK" cancel button "Cancel" giving up after 1
		end if
	end tell
end countdownTimer
 
on finishedDialog() -- [Shared subroutine]
	set timeTaken to round (current date) - startTime rounding as taught in school
	set timeString to my makeNiceT(timeTaken)
	tell application id "com.figure53.QLab.4"
		activate
		display dialog "Done." & return & return & "(That took " & timeString & ".)" with title dialogTitle with icon 1 ¬
			buttons {"OK"} default button "OK" giving up after 60
	end tell
end finishedDialog
 
(* === TIME === *)
 
on makeMSS(howLong) -- [Shared subroutine]
	set howManyMinutes to howLong div 60
	set howManySeconds to howLong mod 60 div 1
	return (howManyMinutes as text) & ":" & my padNumber(howManySeconds, 2)
end makeMSS
 
on makeNiceT(howLong) -- [Shared subroutine]
	if howLong < 1 then
		return "less than a second"
	end if
	set howManyHours to howLong div 3600
	if howManyHours is 0 then
		set hourString to ""
	else if howManyHours is 1 then
		set hourString to "1 hour"
	else
		set hourString to (howManyHours as text) & " hours"
	end if
	set howManyMinutes to howLong mod 3600 div 60
	if howManyMinutes is 0 then
		set minuteString to ""
	else if howManyMinutes is 1 then
		set minuteString to "1 minute"
	else
		set minuteString to (howManyMinutes as text) & " minutes"
	end if
	set howManySeconds to howLong mod 60 div 1
	if howManySeconds is 0 then
		set secondString to ""
	else if howManySeconds is 1 then
		set secondString to "1 second"
	else
		set secondString to (howManySeconds as text) & " seconds"
	end if
	set theAmpersand to ""
	if hourString is not "" then
		if minuteString is not "" and secondString is not "" then
			set theAmpersand to ", "
		else if minuteString is not "" or secondString is not "" then
			set theAmpersand to " and "
		end if
	end if
	set theOtherAmpersand to ""
	if minuteString is not "" and secondString is not "" then
		set theOtherAmpersand to " and "
	end if
	return hourString & theAmpersand & minuteString & theOtherAmpersand & secondString
end makeNiceT
 
(* === TEXT WRANGLING === *)
 
on padNumber(theNumber, minimumDigits) -- [Shared subroutine]
	set paddedNumber to theNumber as text
	repeat while (count paddedNumber) < minimumDigits
		set paddedNumber to "0" & paddedNumber
	end repeat
	return paddedNumber
end padNumber

Add selected files from iTunes and name the cues accordingly (the script will also attempt to remove track numbers from the start of the names); remember to bundle the workspace at some point to get the audio files in the right place:

set userAttemptToRemoveTrackNumbers to true -- Set this to false if you don't mind having track numbers in your cue descriptions
set useriTunesSelectionCountLimit to 100 -- Protect against inadvertently trying to import entire playlists selected in the iTunes sidebar (you can increase this limit)
 
-- Declarations
 
global dialogTitle
set dialogTitle to "Add files from iTunes"
 
-- Check iTunes is running
 
tell application "System Events"
	set iTunesIsOpen to count (processes whose name is "iTunes")
end tell
if iTunesIsOpen is 0 then
	display dialog "iTunes is not running." with title dialogTitle with icon 0 buttons {"OK"} default button "OK" giving up after 5
	return
end if
 
-- Test for an acceptable selection
 
tell application "iTunes"
	set iTunesSelectionCount to count (selection as list)
end tell
if iTunesSelectionCount is 0 then
	display dialog "There is no selection in iTunes." with title dialogTitle with icon 0 buttons {"OK"} default button "OK" giving up after 5
	return
else if iTunesSelectionCount > useriTunesSelectionCountLimit then
	display dialog "The selection in iTunes (" & iTunesSelectionCount & ") is larger than the limit (" & useriTunesSelectionCountLimit & ")." with title dialogTitle ¬
		with icon 0 buttons {"OK"} default button "OK" giving up after 10
	return
end if
 
-- Offer escape hatch
 
if iTunesSelectionCount is 1 then
	set countString to "file"
else
	set countString to "files"
end if
 
display dialog "Adding " & iTunesSelectionCount & " selected " & countString & " from iTunes…" with title dialogTitle with icon 1 ¬
	buttons {"Cancel", "OK"} default button "OK" cancel button "Cancel" giving up after 5 -- You have 5s to change your mind
 
-- Get the files
 
tell application "iTunes"
	set selectedFiles to (location of selection) as list
end tell
 
-- Get the names
 
set selectedNames to {}
tell application "System Events"
	repeat with eachItem in selectedFiles
		set end of selectedNames to name of eachItem
	end repeat
end tell
 
-- Attempt to remove track numbers, as necessary
 
if userAttemptToRemoveTrackNumbers is true then
	set cleanedNames to {}
	set currentTIDs to AppleScript's text item delimiters
	set AppleScript's text item delimiters to space
	repeat with eachName in selectedNames
		if first character of first text item of eachName is in "01234567890" then
			set end of cleanedNames to rest of text items of eachName as text
		else
			set end of cleanedNames to eachName
		end if
	end repeat
	set AppleScript's text item delimiters to currentTIDs
else
	set cleanedNames to selectedNames
end if
 
-- Add the files
 
tell front workspace
	repeat with i from 1 to count selectedFiles
		make type "Audio"
		set newCue to last item of (selected as list)
		set file target of newCue to item i of selectedFiles
		set q name of newCue to item i of cleanedNames
	end repeat
end tell
 
display dialog "Done." with title dialogTitle with icon 1 buttons {"OK"} default button "OK" giving up after 5

Add Start Cue below the selected cue with Pre Wait based on its elapsed time:

tell front workspace
 
	try -- This protects against no selection (can't get last item of (selected as list))
 
		set selectedCue to last item of (selected as list)
 
		if q type of selectedCue is not "Audio" or running of selectedCue is false then error -- Need to escape the whole script
 
		set elapsedTime to (percent action elapsed of selectedCue) * (duration of selectedCue)
		-- ###FIXME### As of 4.4.1, "action elapsed" reports differently between clicking in waveform and loading to time when rate ≠ 1
 
		make type "Start"
		set newCue to last item of (selected as list)
		set pre wait of newCue to elapsedTime
 
		set selected to selectedCue
 
	end try
 
end tell

Add triggers to the end of the Main Cue List for cues you have selected in another cue list, and then switch back:

set userCueList to "Main Cue List" -- Use this to specify the name of the cue list that receives the Start Cue(s)
 
-- Declarations
 
global dialogTitle
set dialogTitle to "Add Start Cues"
 
-- Main routine
 
tell front workspace
	try -- Check destination cue list exists
		set startCueList to first cue list whose q name is userCueList
	on error
		display dialog "The destination cue list \"" & userCueList & "\" does not exist." with title dialogTitle with icon 0 ¬
			buttons {"OK"} default button "OK"
		return
	end try
	set startingSelection to selected
	set startingCueList to current cue list
	set originalCueList to q name of current cue list
	if originalCueList is not userCueList then
		set selectedCues to (selected as list)
		set current cue list to startCueList
		repeat with eachCue in selectedCues
			make type "Start"
			set newCue to last item of (selected as list)
			set cue target of newCue to eachCue
			set nameString to "Start"
			if originalCueList is not "" then
				set nameString to nameString & " | " & originalCueList
			end if
			set eachNumber to q number of eachCue
			if eachNumber is not "" then
				set nameString to nameString & " | Q " & eachNumber
			end if
			set eachName to q list name of eachCue
			if eachName is not "" then
				set nameString to nameString & " | " & eachName
			end if
			set q name of newCue to nameString
		end repeat
		delay 1 -- Let you see it
		set selected to startingSelection
		set current cue list to startingCueList
	end if
 
end tell

Create Arm Cue targeting selected cue as previous cue; doesn't fire in a cart:

tell front workspace
	if q type of current cue list is "Cart" then return -- This will stop the script if we're in a cart, as it doesn't make sense to continue!
	try -- This protects against no selection (can't get last item of (selected as list))
		set originalCue to last item of (selected as list)
		make type "Arm"
		set newCue to last item of (selected as list)
		set cue target of newCue to originalCue
		set targetName to q list name of originalCue
		if targetName is "" then
			set targetName to q display name of originalCue
		end if
		set q name of newCue to "Arm: " & targetName
		set originalCueIsIn to parent of originalCue
		if parent of newCue is originalCueIsIn then -- Only reorder the cues if they are in the same group/cue list
			set originalCueID to uniqueID of originalCue
			set newCueID to uniqueID of newCue
			move cue id originalCueID of originalCueIsIn to after cue id newCueID of originalCueIsIn
		end if
	end try
end tell

Create Disarm Cue targeting selected cue as next cue; doesn't fire in a cart:

tell front workspace
	if q type of current cue list is "Cart" then return -- This will stop the script if we're in a cart, as it doesn't make sense to continue!
	try -- This protects against no selection (can't get last item of (selected as list))
		set originalCue to last item of (selected as list)
		make type "Disarm"
		set newCue to last item of (selected as list)
		set cue target of newCue to originalCue
		set targetName to q list name of originalCue
		if targetName is "" then
			set targetName to q display name of originalCue
		end if
		set q name of newCue to "Disarm: " & targetName
	end try
end tell

Make a series of MIDI Cues which increment the parameter you specify; doesn't fire in a cart:

-- Best run as a separate process so it can be happening in the background
 
-- This script can optionally convert note numbers in MIDI Cues to note names: use the variables below to set the behaviour
 
set userMIDIPatch to false -- Set to false to use QLab default for the cues made, or set to 1-8 for MIDI patch 1-8
set userMinimumTimeBetweenCues to 0.01 -- How long to allow between MIDI Cues when sending clusters (eg: Bank/PC)?
set userHowManyPossible to 1000 -- Limit series with increment of 0 to this many cues!
set userMIDIConversionMode to item 3 of {"Numbers", "Names", "Both"} -- Use this to choose how MIDI note values will be included in cue names
set userNote60Is to item 1 of {"C3", "C4"} -- Use this to set which note name corresponds to note 60
 
-- Explanations
 
set theExplanation to "This script will create a series of MIDI Cues which increment the parameter you specify.
 
For example, you can generate quickly a series of Program Changes for recalling scenes on a mixing desk, " & ¬
	"or a series of Note Ons for triggering a sampler or some other device."
 
-- Declarations
 
global dialogTitle
set dialogTitle to "Go ahead make MIDI"
 
global userMIDIConversionMode, noteNames, octaveConvention
set noteNames to {"C", "C#", "D", "D#", "E", "F", "F#", "G", "G#", "A", "A#", "B"}
if userNote60Is is "C3" then
	set octaveConvention to -2
else
	set octaveConvention to -1
end if
 
set kindChoices to {"Note On: fixed note number, incrementing velocity", "Note On: fixed velocity, incrementing note number", ¬
	"Control Change: fixed controller number, incrementing value", "Control Change: fixed value, incrementing controller number", "Program Change", ¬
	"Bank Select (Coarse) / Program Change, ie: CC00 + Program Change"}
set kindCommands to {"Note On", "Note On", "Control Change", "Control Change", "Program Change", "CC00/PC"}
set kindByteOne to {"fixed", "variable", "fixed", "variable", "variable", "variable"}
set kindByteTwo to {"variable", "fixed", "variable", "fixed", "", ""}
set kindQuestionHeader to {"Making Note On cues with incrementing velocity.", "Making Note On cues with incrementing note number.", ¬
	"Making Control Change cues with incrementing value.", "Making Control Change cues with incrementing controller number.", ¬
	"Making Program Change cues.", "Making Bank Select (Coarse) / Program Change cues."}
set kindQuestionOne to {"Enter the fixed note number:", "Enter the note number for the first cue:", "Enter the fixed controller number:", ¬
	"Enter the controller number for the first cue:", "Enter the Program Change number for the first cue:", ¬
	"Enter the combined Bank Select (Coarse) / Program Change number for the first cue (eg: for Bank 2 Program 3 enter 2 * 128 + 3 = 259):"}
set kindQuestionTwo to {"Enter the velocity for the first cue:", "Enter the fixed velocity:", "Enter the value for the first cue:", "Enter the fixed value:", "", ""}
set kindQuestionInc to "Enter the increment:"
set kindQuestionMany to "Enter the number of cues to create (maximum "
set channelChoices to {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16}
 
-- Find out what we are doing
 
tell application id "com.figure53.QLab.4" to tell front workspace
 
	if q type of current cue list is "Cart" then return -- This will stop the script if we're in a cart, as it doesn't make sense to continue!
 
	set theKind to my pickFromList(kindChoices, theExplanation & return & return & "Choose which kind of series would you like to make:")
 
	repeat with i from 1 to count kindChoices
		if theKind is item i of kindChoices then
			set commandType to item i of kindCommands
			if commandType is "CC00/PC" then
				set byteOneMax to 127 * 128 + 127
			else
				set byteOneMax to 127
			end if
			set byteOne to item i of kindByteOne
			set byteTwo to item i of kindByteTwo
			set questionHeader to item i of kindQuestionHeader
			set questionOne to item i of kindQuestionOne
			set questionTwo to item i of kindQuestionTwo
			set questionInc to kindQuestionInc
			set questionMany to kindQuestionMany
			exit repeat
		end if
	end repeat
 
	set theChannel to my pickFromList(channelChoices, questionHeader & return & return & "Choose the MIDI channel for the cues:")
 
	set byteOneStart to my enterANumberWithRangeWithCustomButton(questionHeader & return & return & questionOne, "", ¬
		0, true, byteOneMax, true, true, {}, "OK")
	set currentByteOne to byteOneStart
	set byteOneIncrement to 0
 
	if byteOne is "variable" then
		set byteOneIncrement to my enterANumberWithRangeWithCustomButton(questionHeader & return & return & questionInc, "", ¬
			-byteOneStart, true, (byteOneMax - byteOneStart), true, true, {}, "OK")
		if byteOneIncrement < 0 then
			set howManyPossible to 1 - (round (byteOneStart / byteOneIncrement) rounding up)
		else if byteOneIncrement > 0 then
			set howManyPossible to 1 + (round ((byteOneMax - byteOneStart) / byteOneIncrement) rounding down)
		else
			set howManyPossible to userHowManyPossible
		end if
	end if
 
	if byteTwo is not "" then
		set byteTwoStart to my enterANumberWithRangeWithCustomButton(questionHeader & return & return & questionTwo, "", ¬
			0, true, 127, true, true, {}, "OK")
	else
		set byteTwoStart to 0
	end if
	set currentByteTwo to byteTwoStart
	set byteTwoIncrement to 0
 
	if byteTwo is "variable" then
		set byteTwoIncrement to my enterANumberWithRangeWithCustomButton(questionHeader & return & return & questionInc, "", ¬
			-byteTwoStart, true, (127 - byteTwoStart), true, true, {}, "OK")
		if byteTwoIncrement < 0 then
			set howManyPossible to 1 - (round (byteTwoStart / byteTwoIncrement) rounding up)
		else if byteTwoIncrement > 0 then
			set howManyPossible to 1 + (round ((127 - byteTwoStart) / byteTwoIncrement) rounding down)
		else
			set howManyPossible to userHowManyPossible
		end if
	end if
 
	set howMany to my enterANumberWithRangeWithCustomButton(questionHeader & return & return & questionMany & howManyPossible & "):", "", ¬
		1, true, howManyPossible, true, true, {}, "OK")
 
	set customNaming to text returned of (display dialog questionHeader & return & return & ¬
		"Enter a base string for naming the cues, or press return to use the default naming option:" with title ¬
		dialogTitle default answer "" buttons {"Cancel", "OK"} default button "OK" cancel button "Cancel")
	if customNaming is not "" then
		if customNaming does not end with " " and (byteOneIncrement is not 0 or byteTwoIncrement is not 0) then
			set customNaming to customNaming & " "
		end if
	end if
 
	-- Do it
 
	display dialog "One moment caller…" with title dialogTitle with icon 1 buttons {"OK"} default button "OK" giving up after 1
 
	if commandType is not "CC00/PC" then
 
		set theCommand to commandType
 
		repeat howMany times
 
			make type "MIDI"
			set newCue to last item of (selected as list)
			if userMIDIPatch is not false then
				set patch of newCue to userMIDIPatch
			end if
			set channel of newCue to theChannel
			set byte one of newCue to currentByteOne
			set nameString to "Channel " & theChannel & " | " & theCommand & " | "
			if theCommand is "Note On" then
				set command of newCue to note_on
				set byte two of newCue to currentByteTwo
				set nameString to nameString & my convertMIDINoteValues(currentByteOne, currentByteTwo)
			else if theCommand is "Control Change" then
				set command of newCue to control_change
				set byte two of newCue to currentByteTwo
				set nameString to nameString & currentByteOne & " @ " & currentByteTwo
			else if theCommand is "Program Change" then
				set command of newCue to program_change
				set nameString to nameString & currentByteOne
			end if
			if customNaming is "" then
				set q name of newCue to nameString
			else if byteOneIncrement is not 0 then
				set q name of newCue to customNaming & currentByteOne
			else if byteTwoIncrement is not 0 then
				set q name of newCue to customNaming & currentByteTwo
			else
				set q name of newCue to customNaming
			end if
			set currentByteOne to currentByteOne + byteOneIncrement
			set currentByteTwo to currentByteTwo + byteTwoIncrement
 
		end repeat
 
	else
 
		repeat howMany times
 
			set currentBank to currentByteOne div 128
			set currentProgram to currentByteOne mod 128
 
			make type "Group"
			set groupCue to last item of (selected as list)
			set mode of groupCue to timeline
 
			make type "MIDI"
			set newCue to last item of (selected as list)
			if userMIDIPatch is not false then
				set patch of newCue to userMIDIPatch
			end if
			set channel of newCue to theChannel
			set command of newCue to control_change
			set byte one of newCue to 0
			set byte two of newCue to currentBank
			set q name of newCue to "Channel " & theChannel & " | Control Change | 0 @ " & currentBank
			set newCueID to uniqueID of newCue
			move cue id newCueID of parent of newCue to end of groupCue
 
			make type "MIDI"
			set newCue to last item of (selected as list)
			if userMIDIPatch is not false then
				set patch of newCue to userMIDIPatch
			end if
			set channel of newCue to theChannel
			set command of newCue to program_change
			set byte one of newCue to currentProgram
			set q name of newCue to "Channel " & theChannel & " | Program Change | " & currentProgram
			set newCueID to uniqueID of newCue
			move cue id newCueID of parent of newCue to end of groupCue
			set pre wait of newCue to userMinimumTimeBetweenCues
 
			if customNaming is "" then
				set q name of groupCue to "Channel " & theChannel & ¬
					" | Bank | " & currentBank & " | Program Change | " & currentProgram & " | Combined value: " & currentByteOne
			else if byteOneIncrement is not 0 then
				set q name of groupCue to customNaming & currentByteOne
			else
				set q name of groupCue to customNaming
			end if
 
			set currentByteOne to currentByteOne + byteOneIncrement
 
		end repeat
 
	end if
 
	display dialog "Done." with title dialogTitle with icon 1 buttons {"OK"} default button "OK" giving up after 60
 
end tell
 
-- Subroutines
 
(* === INPUT === *)
 
on enterANumberWithRangeWithCustomButton(thePrompt, defaultAnswer, ¬
	lowRange, acceptEqualsLowRange, highRange, acceptEqualsHighRange, integerOnly, customButton, defaultButton) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		set theQuestion to ""
		repeat until theQuestion is not ""
			set {theQuestion, theButton} to {text returned, button returned} of (display dialog thePrompt with title dialogTitle ¬
				default answer defaultAnswer buttons (customButton as list) & {"Cancel", "OK"} default button defaultButton cancel button "Cancel")
			if theButton is customButton then
				set theAnswer to theButton
				exit repeat
			end if
			try
				if integerOnly is true then
					set theAnswer to theQuestion as integer -- Detects non-numeric strings
					if theAnswer as text is not theQuestion then -- Detects non-integer input
						set theQuestion to ""
					end if
				else
					set theAnswer to theQuestion as number -- Detects non-numeric strings
				end if
				if lowRange is not false then
					if acceptEqualsLowRange is true then
						if theAnswer < lowRange then
							set theQuestion to ""
						end if
					else
						if theAnswer ≤ lowRange then
							set theQuestion to ""
						end if
					end if
				end if
				if highRange is not false then
					if acceptEqualsHighRange is true then
						if theAnswer > highRange then
							set theQuestion to ""
						end if
					else
						if theAnswer ≥ highRange then
							set theQuestion to ""
						end if
					end if
				end if
			on error
				set theQuestion to ""
			end try
		end repeat
		return theAnswer
	end tell
end enterANumberWithRangeWithCustomButton
 
on pickFromList(theChoice, thePrompt) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		choose from list theChoice with prompt thePrompt with title dialogTitle default items item 1 of theChoice
		if result is not false then
			return item 1 of result
		else
			error number -128
		end if
	end tell
end pickFromList
 
(* === TEXT WRANGLING === *)
 
on configureNoteNameString(noteNumber) -- [Shared subroutine]
	set theOctave to (noteNumber div 12) + octaveConvention
	set theNote to item (noteNumber mod 12 + 1) of noteNames
	set noteNameString to theNote & theOctave
	return noteNameString
end configureNoteNameString
 
on convertMIDINoteValues(noteNumber, noteVelocity) -- [Shared subroutine]
	if userMIDIConversionMode is "Numbers" then
		return noteNumber & " @ " & noteVelocity
	else if userMIDIConversionMode is "Names" then
		return my configureNoteNameString(noteNumber) & " @ " & noteVelocity
	else if userMIDIConversionMode is "Both" then
		return noteNumber & " @ " & noteVelocity & " | " & my configureNoteNameString(noteNumber)
	end if
end convertMIDINoteValues

Add some ugly cues to make it possible to crash ahead before the next domino has toppled; or, looking at it another way, if you don't take the cue it will GO anyway when the timer (5s) runs out…; doesn't fire in a cart:

set userDuration to 5
 
tell front workspace
	if q type of current cue list is "Cart" then return -- This will stop the script if we're in a cart, as it doesn't make sense to continue!
	try -- This protects against no selection (can't get last item of (selected as list))
		set originalCue to last item of (selected as list)
		set continue mode of originalCue to auto_continue
		make type "Start"
		set newStartCue to last item of (selected as list)
		set cue target of newStartCue to current cue list
		set pre wait of newStartCue to userDuration
		set q name of newStartCue to "     stop…"
		make type "Stop"
		set newStopCue to last item of (selected as list)
		set cue target of newStopCue to newStartCue
		set q name of newStopCue to "     …carry on"
		set continue mode of newStopCue to auto_continue
	end try
end tell

Toggle arming of selected cue(s) (the script will arm/disarm the current cue list if no cues are selected):

tell front workspace
	set selectedCues to (selected as list)
	if (count selectedCues) is 0 then -- If no cues are selected arm/disarm the current cue list
		set armed of current cue list to not armed of current cue list
	else
		repeat with eachCue in reverse of selectedCues -- Reversed so as to do a Group Cue's children before it
			set armed of eachCue to not armed of eachCue
		end repeat
	end if
end tell

Arm, disarm or toggle arming of all cues in the workspace whose name contains the string you enter (not case-sensitive); the string is copied to the Clipboard for you to paste in next time:

set userDefaultSearchString to "REHEARSAL" -- Use this to specify the default search string
 
-- Declarations
 
global dialogTitle
set dialogTitle to "Batch disarm"
 
-- Get the search string
 
set {theText, theButton} to {text returned, button returned} of (display dialog ¬
	"Arm/disarm cues whose name contains (return an empty string to cancel):" with title dialogTitle with icon 1 ¬
	default answer userDefaultSearchString buttons {"Toggle", "Arm", "Disarm"} default button "Disarm")
 
-- Check for cancel
 
if theText is "" then
	error number -128
end if
 
-- Copy the search string to the Clipboard and arm/disarm the cues
 
set the clipboard to theText as text
 
tell front workspace
	set foundCues to cues whose q list name contains theText
	set foundCuesRef to a reference to foundCues
	repeat with eachCue in reverse of foundCuesRef -- Reversed so as to do a Group Cue's children before it
		if theButton is "Arm" then
			set armed of eachCue to true
		else if theButton is "Disarm" then
			set armed of eachCue to false
		else
			set armed of eachCue to not armed of eachCue
		end if
	end repeat
end tell

Clear Cue Number of selected cue(s) that aren't directly in a cue list (the script will also optionally act on children of selected Group Cues):

set userEnterIntoGroups to true -- Set this to false if you don't want the script to act on children of selected Group Cues
 
tell front workspace
	set cuesToProcess to (selected as list)
	set selectedCount to count cuesToProcess
	set currentCueList to current cue list
	set i to 0
	repeat until i = (count cuesToProcess)
		set eachCue to item (i + 1) of cuesToProcess
		if i < selectedCount then -- Don't need to check parentage of cues added to the list as children of selected Group Cues
			if parent of eachCue is not currentCueList then
				set q number of eachCue to ""
			end if
		else
			set q number of eachCue to ""
		end if
		if userEnterIntoGroups is true then
			if q type of eachCue is "Group" then
				set cuesToProcess to cuesToProcess & cues of eachCue
			end if
		end if
		set i to i + 1
	end repeat
end tell

Renumber selected cue(s) using a sequence list, starting with the number you enter and incrementing the (integer) numerical part at the end; QLab's logic of skipping existing numbers is modelled:

set userDefaultIncrement to 1 -- Use this to specify the default increment between numbers presented in the dialog
 
-- Declarations
 
global dialogTitle
set dialogTitle to "Renumber with a prefix"
 
-- Check the Clipboard for a previous prefix
 
try
	set clipboardContents to the clipboard as text
on error
	set clipboardContents to ""
end try
 
if clipboardContents contains return or clipboardContents contains linefeed then -- Slight protection against spurious Clipboard contents
	set clipboardContents to ""
end if
 
-- Main routine
 
set startingNumber to enterSomeTextWithIcon("Enter the Cue Number for the first selected cue:", clipboardContents, true)
 
set thePrefix to startingNumber
set theSuffix to ""
set nonNumberFound to false
 
repeat with i from (count characters of startingNumber) to 1 by -1
	if character i of startingNumber is not in characters of "0123456789" then
		set nonNumberFound to true
		set thePrefix to (characters 1 thru i of startingNumber) as text
		try -- If the last character is not a number then theSuffix remains as ""
			set theSuffix to (characters (i + 1) thru end of startingNumber) as text
		end try
		exit repeat
	end if
end repeat
 
if nonNumberFound is false then -- Edge case where the text entered is a number with no prefix
	set thePrefix to ""
	set theSuffix to startingNumber
end if
 
set theSuffix to theSuffix as integer
 
set theIncrement to enterANumberWithIcon("Enter the increment:", userDefaultIncrement)
 
tell front workspace
 
	set selectedCues to (selected as list)
 
	-- Clear existing Cue Numbers
 
	repeat with eachCue in selectedCues
		set q number of eachCue to ""
	end repeat
 
	-- Get a list of numbers that can't be used
 
	set allNumbers to q number of cues
	set allNumbersRef to a reference to allNumbers
 
	-- Renumber the cues
 
	repeat with eachCue in selectedCues
		set newNumber to (thePrefix & theSuffix) as text
		repeat until newNumber is not in allNumbersRef -- If the number is in use, then skip it
			set theSuffix to theSuffix + theIncrement
			set newNumber to (thePrefix & theSuffix) as text
		end repeat
		set q number of eachCue to newNumber
		set theSuffix to theSuffix + theIncrement
	end repeat
 
end tell
 
-- Copy the prefix to the Clipboard
 
set the clipboard to startingNumber as text
 
-- Subroutines
 
(* === INPUT === *)
 
on enterANumberWithIcon(thePrompt, defaultAnswer) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		set theQuestion to ""
		repeat until theQuestion is not ""
			set theQuestion to text returned of (display dialog thePrompt with title dialogTitle with icon 1 ¬
				default answer defaultAnswer buttons {"Cancel", "OK"} default button "OK" cancel button "Cancel")
			try
				set theAnswer to theQuestion as number
			on error
				set theQuestion to ""
			end try
		end repeat
		return theAnswer
	end tell
end enterANumberWithIcon
 
on enterSomeTextWithIcon(thePrompt, defaultAnswer, emptyAllowed) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		set theAnswer to ""
		repeat until theAnswer is not ""
			set theAnswer to text returned of (display dialog thePrompt with title dialogTitle with icon 1 ¬
				default answer defaultAnswer buttons {"Cancel", "OK"} default button "OK" cancel button "Cancel")
			if emptyAllowed is true then exit repeat
		end repeat
		return theAnswer
	end tell
end enterSomeTextWithIcon

Append the string you enter to the Cue Numbers of the selected cue(s):

-- Declarations
 
global dialogTitle
set dialogTitle to "Add suffix to Cue Number"
 
-- Check the Clipboard for a previous suffix
 
try
	set clipboardContents to the clipboard as text
on error
	set clipboardContents to ""
end try
 
if clipboardContents contains return or clipboardContents contains linefeed then -- Slight protection against spurious Clipboard contents
	set clipboardContents to ""
end if
 
-- Main routine
 
set theSuffix to enterSomeTextWithIcon("Enter the suffix to append:", clipboardContents, true)
 
tell front workspace
	repeat with eachCue in (selected as list)
		set q number of eachCue to (q number of eachCue & theSuffix)
	end repeat
end tell
 
-- Copy the suffix to the Clipboard
 
set the clipboard to theSuffix as text
 
-- Subroutines
 
(* === INPUT === *)
 
on enterSomeTextWithIcon(thePrompt, defaultAnswer, emptyAllowed) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		set theAnswer to ""
		repeat until theAnswer is not ""
			set theAnswer to text returned of (display dialog thePrompt with title dialogTitle with icon 1 ¬
				default answer defaultAnswer buttons {"Cancel", "OK"} default button "OK" cancel button "Cancel")
			if emptyAllowed is true then exit repeat
		end repeat
		return theAnswer
	end tell
end enterSomeTextWithIcon

Reset name of selected cue(s) (the script will reset the name of an Audio, Video or MIDI File Cue to its File Target, name other types of cue based on their type and Cue Target, name MIDI Cues based on their parameters, or reset Network Cues to their default names; other cues that have neither File nor Cue Target are unaffected):

-- This script can optionally convert note numbers in MIDI Cues to note names and mark looped cues: use the variables below to set the behaviour
 
set userMIDIConversionMode to item 1 of {"Numbers", "Names", "Both"} -- Use this to choose how MIDI note values will be included in cue names
set userNote60Is to item 1 of {"C3", "C4"} -- Use this to set which note name corresponds to note 60
 
set userFlagInfiniteLoops to true -- Set whether to append the comments below to the default names of Audio & Video Cues that contain infinite loops
set userInfiniteCueFlag to "!! Infinite loop !!"
set userInfiniteSliceFlag to "!! Infinite slice !!"
 
-- Declarations
 
global userMIDIConversionMode, noteNames, octaveConvention
set noteNames to {"C", "C#", "D", "D#", "E", "F", "F#", "G", "G#", "A", "A#", "B"}
if userNote60Is is "C3" then
	set octaveConvention to -2
else
	set octaveConvention to -1
end if
 
set mscCommandFormat to {1, "Lighting (General)", 2, "Moving Lights", 3, "Color Changers", 4, "Strobes", 5, "Lasers", 6, "Chasers", ¬
	16, "Sound (General)", 17, "Music", 18, "CD Players", 19, "EPROM Playback", 20, "Audio Tape Machines", 21, "Intercoms", 22, "Amplifiers", ¬
	23, "Audio Effects Devices", 24, "Equalizers", 32, "Machinery (General)", 33, "Rigging", 34, "Flys", 35, "Lifts", 36, "Turntables", 37, "Trusses", ¬
	38, "Robots", 39, "Animation", 40, "Floats", 41, "Breakaways", 42, "Barges", 48, "Video (General)", 49, "Video Tape Machines", ¬
	50, "Video Cassette Machines", 51, "Video Disc Players", 52, "Video Switchers", 53, "Video Effects", 54, "Video Character Generators", ¬
	55, "Video Still Stores", 56, "Video Monitors", 64, "Projection (General)", 65, "Film Projectors", 66, "Slide Projectors", 67, "Video Projectors", ¬
	68, "Dissolvers", 69, "Shutter Controls", 80, "Process Control (General)", 81, "Hydraulic Oil", 82, "H2O", 83, "CO2", 84, "Compressed Air", ¬
	85, "Natural Gas", 86, "Fog", 87, "Smoke", 88, "Cracked Haze", 96, "Pyrotechnics (General)", 97, "Fireworks", 98, "Explosions", 99, "Flame", ¬
	100, "Smoke Pots", 127, "All Types"}
set mscCommandNumber to {1, "GO", 2, "STOP", 3, "RESUME", 4, "TIMED_GO", 5, "LOAD", 6, "SET", 7, "FIRE", 8, "ALL_OFF", ¬
	9, "RESTORE", 10, "RESET", 11, "GO_OFF", 16, "GO/JAM_CLOCK", 17, "STANDBY_+", 18, "STANDBY_-", 19, "SEQUENCE_+", ¬
	20, "SEQUENCE_-", 21, "START_CLOCK", 22, "STOP_CLOCK", 23, "ZERO_CLOCK", 24, "SET_CLOCK", 25, "MTC_CHASE_ON", ¬
	26, "MTC_CHASE_OFF", 27, "OPEN_CUE_LIST", 28, "CLOSE_CUE_LIST", 29, "OPEN_CUE_PATH", 30, "CLOSE_CUE_PATH"}
set mscCommandTakesQNumber to {1, 2, 3, 4, 5, 11, 16}
set mscCommandTakesQList to {1, 2, 3, 4, 5, 11, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28}
set mscCommandTakesQPath to {1, 2, 3, 4, 5, 11, 16, 29, 30}
set mscCommandTakesMacro to {7}
set mscCommandTakesControl to {6}
set mscCommandTakesTC to {4, 6, 24}
 
-- Main routine
 
tell front workspace
	repeat with eachCue in (selected as list)
		try -- Audio, Video or MIDI File Cues
			set eachFile to file target of eachCue as alias
			tell application "System Events"
				set eachNameList to {name of eachFile}
			end tell
			try
				if infinite loop of eachCue is true then
					set end of eachNameList to userInfiniteCueFlag
				end if
				if last slice infinite loop of eachCue is true then
					set end of eachNameList to userInfiniteSliceFlag
				end if
			end try
			set currentTIDs to AppleScript's text item delimiters
			set AppleScript's text item delimiters to " | "
			set q name of eachCue to eachNameList as text
			set AppleScript's text item delimiters to currentTIDs
		on error
			try -- Fade, Start, Stop, Pause, Load, Reset, Devamp, GoTo, Target, Arm or Disarm Cues
				set eachTarget to q list name of cue target of eachCue
				if eachTarget is "" then
					set eachTarget to q display name of cue target of eachCue
				end if
				set eachType to q type of eachCue
				if eachType is "Fade" then
					if stop target when done of eachCue is true then
						set q name of eachCue to "Fade out: " & eachTarget
					else
						set q name of eachCue to "Fade: " & eachTarget
					end if
				else
					set q name of eachCue to eachType & ": " & eachTarget
				end if
			on error
				try -- MIDI Cues
					set messageType to message type of eachCue
					if messageType is voice then
						set eachChannel to channel of eachCue
						set eachCommand to command of eachCue
						if eachCommand is note_on then
							set byteOne to byte one of eachCue
							set byteTwo to byte two of eachCue
							set q name of eachCue to "Channel " & eachChannel & " | Note On | " & my convertMIDINoteValues(byteOne, byteTwo)
						else if eachCommand is note_off then
							set byteOne to byte one of eachCue
							set byteTwo to byte two of eachCue
							set q name of eachCue to "Channel " & eachChannel & " | Note Off | " & my convertMIDINoteValues(byteOne, byteTwo)
						else if eachCommand is program_change then
							set byteOne to byte one of eachCue
							set q name of eachCue to "Channel " & eachChannel & " | Program Change | " & byteOne
						else if eachCommand is control_change then
							set byteOne to byte one of eachCue
							set byteTwo to byte two of eachCue
							if integrated fade of eachCue is disabled then
								set q name of eachCue to "Channel " & eachChannel & " | Control Change | " & byteOne & " @ " & byteTwo
							else
								set endValue to end value of eachCue
								set q name of eachCue to "Channel " & eachChannel & " | Control Change | " & byteOne & " @ " & byteTwo ¬
									& " … " & endValue
							end if
						else if eachCommand is key_pressure then
							set byteOne to byte one of eachCue
							set byteTwo to byte two of eachCue
							if integrated fade of eachCue is disabled then
								set q name of eachCue to "Channel " & eachChannel & " | Key Pressure | " & my convertMIDINoteValues(byteOne, byteTwo)
							else
								set endValue to end value of eachCue
								set q name of eachCue to ¬
									"Channel " & eachChannel & " | Key Pressure | " & my convertMIDINoteValues(byteOne, byteTwo & " … " & endValue)
							end if
						else if eachCommand is channel_pressure then
							set byteOne to byte one of eachCue
							set q name of eachCue to "Channel " & eachChannel & " | Channel Pressure | " & byteOne
							if integrated fade of eachCue is disabled then
							else
								set endValue to end value of eachCue
								set q name of eachCue to "Channel " & eachChannel & " | Channel Pressure | " & byteOne & " … " & endValue
							end if
						else if eachCommand is pitch_bend then
							set byteCombo to (byte combo of eachCue) - 8192
							if integrated fade of eachCue is disabled then
								set q name of eachCue to "Channel " & eachChannel & " | Pitch Bend | " & byteCombo
							else
								set endValue to (end value of eachCue) - 8192
								set q name of eachCue to "Channel " & eachChannel & " | Pitch Bend | " & byteCombo & " … " & endValue
							end if
						end if
					else if messageType is msc then
						set mscProperties to {}
						set mscEmptyQNumber to false
						set mscEmptyQList to false
						set end of mscProperties to my lookUp(command format of eachCue, mscCommandFormat)
						set end of mscProperties to {"Device ID " & deviceID of eachCue}
						set mscCommand to command number of eachCue
						set end of mscProperties to my lookUp(mscCommand, mscCommandNumber)
						if mscCommand is in mscCommandTakesQNumber then
							set mscQNumber to q_number of eachCue
							if mscQNumber is not "" then
								set end of mscProperties to "Q " & mscQNumber
							else
								set mscEmptyQNumber to true
							end if
						end if
						if mscCommand is in mscCommandTakesQList and mscEmptyQNumber is false then
							set mscQList to q_list of eachCue
							if mscQList is not "" then
								set end of mscProperties to "List " & mscQList
							else
								set mscEmptyQList to true
							end if
						end if
						if mscCommand is in mscCommandTakesQPath and mscEmptyQNumber is false and mscEmptyQList is false then
							set mscQPath to q_path of eachCue
							if mscQPath is not "" then set end of mscProperties to "Path " & mscQPath
						end if
						if mscCommand is in mscCommandTakesMacro then
							set end of mscProperties to macro of eachCue
						end if
						if mscCommand is in mscCommandTakesControl then
							set end of mscProperties to (control number of eachCue & " @ " & control value of eachCue) as text
						end if
						if mscCommand is in mscCommandTakesTC and send time with set of eachCue is true then
							set end of mscProperties to my padNumber(hours of eachCue, 2) & ¬
								":" & my padNumber(minutes of eachCue, 2) & ¬
								":" & my padNumber(seconds of eachCue, 2) & ¬
								":" & my padNumber(frames of eachCue, 2) & ¬
								"/" & my padNumber(subframes of eachCue, 2) -- Not sophisticated enough to use ";" for drop frame rates
						end if
						set currentTIDs to AppleScript's text item delimiters
						set AppleScript's text item delimiters to " | "
						set q name of eachCue to mscProperties as text
						set AppleScript's text item delimiters to currentTIDs
					else
						set q name of eachCue to "MIDI SysEx"
					end if
				on error -- Network Cues
					if q type of eachCue is "Network" then
						set q name of eachCue to "" -- Reset to default
					end if
				end try
			end try
		end try
	end repeat
end tell
 
-- Subroutines
 
(* === DATA WRANGLING === *)
 
on lookUp(lookUpValue, lookUpTable) -- [Shared subroutine]
	repeat with i from 1 to (count lookUpTable) by 2
		if lookUpValue is item i of lookUpTable then
			return item (i + 1) of lookUpTable
		end if
	end repeat
end lookUp
 
(* === TEXT WRANGLING === *)
 
on configureNoteNameString(noteNumber) -- [Shared subroutine]
	set theOctave to (noteNumber div 12) + octaveConvention
	set theNote to item (noteNumber mod 12 + 1) of noteNames
	set noteNameString to theNote & theOctave
	return noteNameString
end configureNoteNameString
 
on convertMIDINoteValues(noteNumber, noteVelocity) -- [Shared subroutine]
	if userMIDIConversionMode is "Numbers" then
		return noteNumber & " @ " & noteVelocity
	else if userMIDIConversionMode is "Names" then
		return my configureNoteNameString(noteNumber) & " @ " & noteVelocity
	else if userMIDIConversionMode is "Both" then
		return noteNumber & " @ " & noteVelocity & " | " & my configureNoteNameString(noteNumber)
	end if
end convertMIDINoteValues
 
on padNumber(theNumber, minimumDigits) -- [Shared subroutine]
	set paddedNumber to theNumber as text
	repeat while (count paddedNumber) < minimumDigits
		set paddedNumber to "0" & paddedNumber
	end repeat
	return paddedNumber
end padNumber

Update filename of File Target for selected cue(s) (the script will change the name of the File Target on disk for an Audio, Video or MIDI File Cue to be the same as the custom name of the cue; QLab's display won't update until you change the selection):

tell front workspace
	repeat with eachCue in (selected as list)
		try
			set eachName to q name of eachCue
			if eachName is "" then -- Skip blank names as otherwise you make invisible files!
				error
			end if
			set eachTarget to file target of eachCue as alias
			tell application "System Events"
				set eachExtension to name extension of eachTarget
				if eachName does not end with eachExtension then
					set name of eachTarget to eachName & "." & eachExtension
				else
					set name of eachTarget to eachName
				end if
			end tell
		end try
	end repeat
end tell

Clear Notes of selected cue(s):

/cue/selected/notes ""

Move selected cue(s) to “Cut” cue list:

set userCutList to "Cut" -- Use this to set the name of the cue list to which to move cut cues
 
-- Declarations
 
global dialogTitle
set dialogTitle to "Move cut cues"
 
-- Main routine
 
tell front workspace
 
	try
		set cutList to first cue list whose q name is userCutList
	on error
		display dialog "The destination cue list can not be found…" with title dialogTitle with icon 0 buttons {"OK"} default button "OK" giving up after 5
		return
	end try
	if current cue list is not cutList then
		set selectedCues to (selected as list)
		set selectedCueIDs to {}
		repeat with eachCue in selectedCues
			set end of selectedCueIDs to uniqueID of eachCue
		end repeat
		repeat with eachCueID in selectedCueIDs
			set eachParentID to uniqueID of parent of cue id eachCueID
			if eachParentID is not in selectedCueIDs then -- If the parent cue is being cut too, keep the nested structure
				move cue id eachCueID of cue id eachParentID to end of cutList
			end if
		end repeat
	end if
end tell

Delete selected cue(s) including their File Targets (target files will be moved to the Trash):

tell front workspace
	repeat with eachCue in (selected as list)
		try
			set eachTarget to file target of eachCue
			if eachTarget as text does not contain ".Trash" then
				tell application "Finder"
					delete eachTarget
				end tell
			end if
		end try
		set eachCueID to uniqueID of eachCue
		delete cue id eachCueID of parent of eachCue
	end repeat
end tell

This script will attempt to batch adjust properties of the currently selected cues according to your instructions… (it won't fire unless you have a cue selected, but once running you can choose to act on all cues):

-- ###FIXME### Impact of housing such a large script in the workspace unknown!
-- ###FIXME### Testing has not been _exhaustive_, for obvious reasons!
-- ###FIXME### Unclear whether script can run in the background while you continue working in QLab (or elsewhere)
-- ###TODO### Add Gangs, MSC command formats?
-- ###TODO### Include "considering case" option for searches
 
-- Best run as a separate process so it can be happening in the background
 
set userEscapeHatchInterval to 50 -- Set the number of cues to process between each progress report / opportunity to cancel
 
-- Explanations
 
set theExplanation to "This script will attempt to batch adjust properties of the currently selected cues according to your instructions.
 
There is some error protection, but it is impossible to make this process completely idiot-proof. You should be warned if something threw an error, " & ¬
	"but it's not possible to track exactly what it was."
 
-- Declarations
 
global dialogTitle, qLabMaxAudioInputs, qLabMaxAudioChannels, userEscapeHatchInterval, startTime, ohDear, abortAbort
set dialogTitle to "Batch adjust selected"
 
set qLabMaxAudioInputs to 24
set qLabMaxAudioChannels to 64
 
global subChoiceTimesParameter, subChoiceMIDIParameter, subChoiceMIDICommand, subChoiceAutoload, subChoiceArmed, subChoiceContinueMode, subChoiceMode
(* These lists are also used for lookup within the chosen handlers *)
 
set processChoices to {"Levels", "File Target", "File Target (keeping times)", "Name", "Number", "Notes", "Times", "MIDI", "MSC Device ID", ¬
	"Auto-load", "Armed", "Continue Mode", "Mode", "Patch", "Camera Patch", "Command Text", "…Finished adjusting", "** Set flag to process ALL CUES! **"}
(* Although batch adjusting of Continue Mode is now built-in, it only operates on selected cues – so keeping it for now as this script can affect ALL cues *)
 
set subChoiceName to {"Set/reset", "Basic search & replace", "Add prefix", "Add suffix", "Make series"}
set subChoiceNumber to {"Add prefix", "Add suffix", "Make series"}
set subChoiceNotes to {"Clear", "Set", "Basic search & replace", "Add prefix", "Add suffix"}
set subChoiceTimesParameter to {"Pre Wait", "Duration", "Post Wait"} -- These values can be customised as they are never used explicitly
set subChoiceTimes to {"Set", "Scale", "Add/subtract amount"}
set subChoiceMIDIParameter to {"Command", "Channel", "Byte One", "Byte Two", "Byte Combo", ¬
	"End Value"} -- These values can be customised as they are never used explicitly
set subChoiceMIDICommand to {"Note On", "Note Off", "Program Change", "Control Change", ¬
	"Key Pressure", "Channel Pressure", "Pitch Bend"} -- These values can be customised as they are never used explicitly
set subChoiceMIDI to {"Set", "Scale", "Add/subtract amount", "Make series"}
set subChoiceAutoload to {"On", "Off"} -- These values can be customised as they are never used explicitly
set subChoiceArmed to {"Armed", "Disarmed"} -- These values can be customised as they are never used explicitly
set subChoiceContinueMode to {"Do not continue", "Auto-continue", "Auto-follow"} -- These values can be customised as they are never used explicitly
set subChoiceMode to {"Timeline - Start all children simultaneously", "Start first child and enter into group", "Start first child and go to next cue", ¬
	"Start random child and go to next cue"} -- These values can be customised as they are never used explicitly
set subChoiceCameraPatch to {1, 2, 3, 4, 5, 6, 7, 8}
set subChoiceCommandText to {"Basic search & replace (all text)", ¬
	"Basic search & replace (Instrument Names only)"} -- These values can be customised as they are never used explicitly
 
-- NB: use "false " rather than "false" in lists presented to pickFromList()
 
-- Preamble
 
set theProcess to ""
set firstTime to true
repeat until theProcess is "…Finished adjusting"
 
	set ohDear to false -- A simple flag to detect problems
	set abortAbort to false -- A flag for aborting!
 
	-- Test for a selection; modify options if only one cue selected
 
	if firstTime is true then -- Only need to do this step once
 
		tell application id "com.figure53.QLab.4"
			set theSelection to (selected of front workspace as list)
		end tell
 
		set theSelectionRef to a reference to theSelection
		set countSelection to count theSelectionRef
		if countSelection is 0 then
			return
		end if
 
		if countSelection is 1 then
			set subChoiceName to items 1 through -2 of subChoiceName -- Remove "Make series"
			set subChoiceNumber to items 1 through -2 of subChoiceNumber -- Remove "Make series"
			set subChoiceMIDI to items 1 through -2 of subChoiceMIDI -- Remove "Make series"
		end if
 
	end if
 
	-- Choose a process
 
	set theProcess to pickFromList(processChoices, theExplanation & return & return & ¬
		"So that you can run more than one process, you'll keep coming back to this screen until you hit any \"Cancel\" button, " & ¬
		"or choose \"…Finished adjusting\"." & return & return & "Choose a property category:")
 
	-- Deal with "process ALL CUES" flag
 
	if firstTime is true then -- Only need to do this step once
 
		set processChoices to items 1 through -2 of processChoices -- Remove "** Set flag to process ALL CUES! **"
 
		if theProcess is "** Set flag to process ALL CUES! **" then
 
			tell application id "com.figure53.QLab.4"
				set theSelection to (cues of front workspace as list)
			end tell
 
			set theExplanation to "WARNING: acting on ALL CUES!" & return & "WARNING: acting on ALL CUES!" & return & "WARNING: acting on ALL CUES!"
 
		end if
 
		set firstTime to false
 
	end if
 
	-- Find out more about what we're doing, and then call a subroutine to do it…
 
	if theProcess is "Levels" then
 
		adjustLevels(theSelectionRef, "selected cues")
 
	else if theProcess is "File Target" then
 
		adjustFileTarget(theSelectionRef, "Set", "selected cues")
 
	else if theProcess is "File Target (keeping times)" then
 
		adjustFileTarget(theSelectionRef, "Change", "selected cues")
 
	else if theProcess is "Name" then
 
		set theChoice to pickFromList(subChoiceName, "Choose how you would like to adjust the names of the selected cues:")
 
		if theChoice is "Set/reset" then
			adjustSetName(theSelectionRef, "selected cues")
		else if theChoice is "Basic search & replace" then
			adjustSearchReplaceName(theSelectionRef, "selected cues")
		else if theChoice is "Add prefix" then
			adjustPrefixName(theSelectionRef, "selected cues")
		else if theChoice is "Add suffix" then
			adjustSuffixName(theSelectionRef, "selected cues")
		else if theChoice is "Make series" then
			adjustSeriesName(theSelectionRef, "selected cues")
		end if
 
	else if theProcess is "Number" then
 
		set theChoice to pickFromList(subChoiceNumber, "Choose how you would like to adjust the Cue Numbers of the selected cues:")
 
		if theChoice is "Add prefix" then
			adjustPrefixNumber(theSelectionRef, "selected cues")
		else if theChoice is "Add suffix" then
			adjustSuffixNumber(theSelectionRef, "selected cues")
		else if theChoice is "Make series" then
			adjustSeriesNumber(theSelectionRef, "selected cues")
		end if
 
	else if theProcess is "Notes" then
 
		set theChoice to pickFromList(subChoiceNotes, "Choose how you would like to adjust the Notes of the selected cues " & ¬
			"(NB: scripting of Notes is plain-text only):")
 
		if theChoice is "Clear" then
			adjustClearNotes(theSelectionRef, "selected cues")
		else if theChoice is "Set" then
			adjustSetNotes(theSelectionRef, "selected cues")
		else if theChoice is "Basic search & replace" then
			adjustSearchReplaceNotes(theSelectionRef, "selected cues")
		else if theChoice is "Add prefix" then
			adjustPrefixNotes(theSelectionRef, "selected cues")
		else if theChoice is "Add suffix" then
			adjustSuffixNotes(theSelectionRef, "selected cues")
		end if
 
	else if theProcess is "Times" then
 
		set parameterChoice to pickFromList(subChoiceTimesParameter, "Choose the time parameter to adjust:")
		set theChoice to pickFromList(subChoiceTimes, "Choose how you would like to adjust the " & parameterChoice & " of the selected cues:")
 
		if theChoice is "Set" then
			adjustSetTime(theSelectionRef, parameterChoice, "selected cues")
		else if theChoice is "Scale" then
			adjustScaleTime(theSelectionRef, parameterChoice, "selected cues")
		else if theChoice is "Add/subtract amount" then
			adjustAddSubractTime(theSelectionRef, parameterChoice, "selected cues")
		end if
 
	else if theProcess is "MIDI" then
 
		-- subChoiceMIDIParameter = {"Command", "Channel", "Byte One", "Byte Two", "Byte Combo", "End Value"}
 
		set parameterChoice to pickFromList(subChoiceMIDIParameter, ¬
			"Choose the MIDI parameter to adjust (\"" & item 5 of subChoiceMIDIParameter & "\" will only affect pitch bend commands):")
		if parameterChoice is item 1 of subChoiceMIDIParameter then
			set theChoice to item 1 of subChoiceMIDIParameter
		else if parameterChoice is item 2 of subChoiceMIDIParameter then
			set theChoice to "Set" -- The other options don't make a lot of sense for channel!
		else
			set theChoice to pickFromList(subChoiceMIDI, "Choose how you would like to adjust the " & parameterChoice & " of the selected cues:")
		end if
 
		if theChoice is item 1 of subChoiceMIDIParameter then
			adjustSetMIDICommand(theSelectionRef, "selected cues")
		else if theChoice is "Set" then
			adjustSetMIDI(theSelectionRef, parameterChoice, "selected cues")
		else if theChoice is "Scale" then
			adjustScaleMIDI(theSelectionRef, parameterChoice, "selected cues")
		else if theChoice is "Add/subtract amount" then
			adjustAddSubractMIDI(theSelectionRef, parameterChoice, "selected cues")
		else if theChoice is "Make series" then
			adjustSeriesMIDI(theSelectionRef, parameterChoice, "selected cues")
		end if
 
	else if theProcess is "MSC Device ID" then
 
		adjustDeviceID(theSelectionRef, "selected cues")
 
	else if theProcess is "Auto-load" then
 
		set parameterChoice to pickFromList(subChoiceAutoload, "Set Auto-load of the selected cues to:")
 
		adjustAutoload(theSelectionRef, parameterChoice, "selected cues")
 
	else if theProcess is "Armed" then
 
		set parameterChoice to pickFromList(subChoiceArmed, "Set Armed of the selected cues to:")
 
		adjustArmed(theSelectionRef, parameterChoice, "selected cues")
 
	else if theProcess is "Continue Mode" then
 
		set parameterChoice to pickFromList(subChoiceContinueMode, "Set the Continue Mode of the selected cues to:")
 
		adjustContinueMode(theSelectionRef, parameterChoice, "selected cues")
 
	else if theProcess is "Mode" then
 
		set parameterChoice to pickFromList(subChoiceMode, "Set the Mode of the selected cues to:")
 
		adjustMode(theSelectionRef, parameterChoice, "selected cues")
 
	else if theProcess is "Patch" then
 
		adjustPatch(theSelectionRef, "selected cues")
 
	else if theProcess is "Camera Patch" then
 
		set parameterChoice to pickFromList(subChoiceCameraPatch, "Set the Camera Patch of the selected cues to:")
 
		adjustCameraPatch(theSelectionRef, parameterChoice, "selected cues")
 
	else if theProcess is "Command Text" then
 
		set theChoice to pickFromList(subChoiceCommandText, "Choose how you would like to adjust the Command Text of the selected cues:")
 
		if theChoice is "Basic search & replace (all text)" then
			adjustSearchReplaceCommandText(theSelectionRef, "selected cues", false)
		else if theChoice is "Basic search & replace (Instrument Names only)" then
			adjustSearchReplaceCommandText(theSelectionRef, "selected cues", true)
		end if
 
	end if
 
end repeat
 
-- Subroutines
 
(* === INPUT === *)
 
on enterAnInteger(thePrompt, defaultAnswer) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		set theQuestion to ""
		repeat until theQuestion is not ""
			set theQuestion to text returned of (display dialog thePrompt with title dialogTitle default answer defaultAnswer buttons {"Cancel", "OK"} ¬
				default button "OK" cancel button "Cancel")
			try
				set theAnswer to theQuestion as integer
			on error
				set theQuestion to ""
			end try
		end repeat
		return theAnswer
	end tell
end enterAnInteger
 
on enterANumber(thePrompt, defaultAnswer) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		set theQuestion to ""
		repeat until theQuestion is not ""
			set theQuestion to text returned of (display dialog thePrompt with title dialogTitle default answer defaultAnswer buttons {"Cancel", "OK"} ¬
				default button "OK" cancel button "Cancel")
			try
				set theAnswer to theQuestion as number
			on error
				set theQuestion to ""
			end try
		end repeat
		return theAnswer
	end tell
end enterANumber
 
on enterANumberWithRangeWithCustomButton(thePrompt, defaultAnswer, ¬
	lowRange, acceptEqualsLowRange, highRange, acceptEqualsHighRange, integerOnly, customButton, defaultButton) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		set theQuestion to ""
		repeat until theQuestion is not ""
			set {theQuestion, theButton} to {text returned, button returned} of (display dialog thePrompt with title dialogTitle ¬
				default answer defaultAnswer buttons (customButton as list) & {"Cancel", "OK"} default button defaultButton cancel button "Cancel")
			if theButton is customButton then
				set theAnswer to theButton
				exit repeat
			end if
			try
				if integerOnly is true then
					set theAnswer to theQuestion as integer -- Detects non-numeric strings
					if theAnswer as text is not theQuestion then -- Detects non-integer input
						set theQuestion to ""
					end if
				else
					set theAnswer to theQuestion as number -- Detects non-numeric strings
				end if
				if lowRange is not false then
					if acceptEqualsLowRange is true then
						if theAnswer < lowRange then
							set theQuestion to ""
						end if
					else
						if theAnswer ≤ lowRange then
							set theQuestion to ""
						end if
					end if
				end if
				if highRange is not false then
					if acceptEqualsHighRange is true then
						if theAnswer > highRange then
							set theQuestion to ""
						end if
					else
						if theAnswer ≥ highRange then
							set theQuestion to ""
						end if
					end if
				end if
			on error
				set theQuestion to ""
			end try
		end repeat
		return theAnswer
	end tell
end enterANumberWithRangeWithCustomButton
 
on enterARatio(thePrompt, defaultAnswer) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		set theQuestion to ""
		repeat until theQuestion is not ""
			set theQuestion to text returned of (display dialog thePrompt with title dialogTitle default answer defaultAnswer buttons {"Cancel", "OK"} ¬
				default button "OK" cancel button "Cancel")
			try
				set theAnswer to theQuestion as number
				if theAnswer ≤ 0 then
					set theQuestion to ""
				end if
			on error
				set theQuestion to ""
			end try
		end repeat
		return theAnswer
	end tell
end enterARatio
 
on enterATimeWithCustomButton(thePrompt, defaultAnswer, customButton) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		set theQuestion to ""
		repeat until theQuestion is not ""
			set {theQuestion, theButton} to {text returned, button returned} of (display dialog thePrompt with title dialogTitle ¬
				default answer defaultAnswer buttons (customButton as list) & {"Cancel", "OK"} default button "OK" cancel button "Cancel")
			if theButton is customButton then
				set theAnswer to theButton
				exit repeat
			end if
			try
				set theAnswer to theQuestion as number
				if theAnswer < 0 then
					set theQuestion to ""
				end if
			on error
				if theQuestion contains ":" then
					set theAnswer to my makeSecondsFromM_S(theQuestion)
					if theAnswer is false then
						set theQuestion to ""
					end if
				else
					set theQuestion to ""
				end if
			end try
		end repeat
		return theAnswer
	end tell
end enterATimeWithCustomButton
 
on enterSomeText(thePrompt, defaultAnswer, emptyAllowed) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		set theAnswer to ""
		repeat until theAnswer is not ""
			set theAnswer to text returned of (display dialog thePrompt with title dialogTitle default answer defaultAnswer buttons {"Cancel", "OK"} ¬
				default button "OK" cancel button "Cancel")
			if emptyAllowed is true then exit repeat
		end repeat
		return theAnswer
	end tell
end enterSomeText
 
on pickFromList(theChoice, thePrompt) -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		choose from list theChoice with prompt thePrompt with title dialogTitle default items item 1 of theChoice
		if result is not false then
			return item 1 of result
		else
			error number -128
		end if
	end tell
end pickFromList
 
(* === OUTPUT === *)
 
on startTheClock() -- [Shared subroutine]
	tell application id "com.figure53.QLab.4"
		display dialog "One moment caller…" with title dialogTitle with icon 1 buttons {"OK"} default button "OK" giving up after 1
	end tell
	set startTime to current date
end startTheClock
 
on countdownTimer(thisStep, totalSteps, whichCuesString) -- [Shared subroutine]
	set timeTaken to round (current date) - startTime rounding as taught in school
	set timeString to my makeMSS(timeTaken)
	tell application id "com.figure53.QLab.4"
		if frontmost then
			display dialog "Time elapsed: " & timeString & " – " & thisStep & " of " & totalSteps & " " & whichCuesString & ¬
				" done…" with title dialogTitle with icon 1 buttons {"Cancel", "OK"} default button "OK" cancel button "Cancel" giving up after 1
		end if
	end tell
end countdownTimer
 
on finishedDialogBespoke()
	set timeTaken to round (current date) - startTime rounding as taught in school
	set timeString to my makeNiceT(timeTaken)
	tell application id "com.figure53.QLab.4"
		activate
		if abortAbort is true then
			display dialog "Process aborted due to errors!" with title dialogTitle with icon 0 buttons {"OK"} default button "OK" giving up after 120
		else
			if ohDear is true then
				set ohDearString to " There were some errors, so you should check the results."
				set ohDearIcon to 0
			else
				set ohDearString to ""
				set ohDearIcon to 1
			end if
			display dialog "Done." & ohDearString & return & return & "(That took " & timeString & ".)" with title dialogTitle with icon ohDearIcon ¬
				buttons {"OK"} default button "OK" giving up after 60
		end if
	end tell
end finishedDialogBespoke
 
(* === PROCESSING === *)
 
on adjustLevels(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		-- Get the levels
 
		set validEntry to false
		set previousTry to ""
		repeat until validEntry is true
 
			set levelsString to my enterSomeText("Enter the levels you wish to adjust as
\"row/column/delta\" or \"row/column/@level\"; you can separate multiple entries with spaces.
 
For example, \"0/0/-10 0/2/@-20\" will take 10dB from the Master level (row 0 column 0) and set the Output 2 level (row 0 column 2) to -20dB.", ¬
				previousTry, false)
			set previousTry to levelsString
 
			-- Convert string to array
 
			set currentTIDs to AppleScript's text item delimiters
			set AppleScript's text item delimiters to space
			set levelsWords to text items of levelsString
			set howManyLevels to count levelsWords
			set AppleScript's text item delimiters to "/"
			set backToText to levelsWords as text
			set levelsArray to text items of backToText
			set countLevelsArray to count levelsArray
			set AppleScript's text item delimiters to currentTIDs
 
			-- Check for validity
 
			if howManyLevels * 3 is countLevelsArray then -- First hurdle
				set validEntry to true
				try
					repeat with i from 1 to countLevelsArray by 3
						set eachRow to (item i of levelsArray) as number
						set eachColumn to (item (i + 1) of levelsArray) as number
						set eachLevel to item (i + 2) of levelsArray
						if eachRow < 0 or eachRow > qLabMaxAudioInputs then -- Check for valid row
							set validEntry to false
							exit repeat
						end if
						if eachColumn < 0 or eachColumn > qLabMaxAudioChannels then -- Check for valid column
							set validEntry to false
							exit repeat
						end if
						if eachLevel does not start with "@" then -- Check for valid level
							if (eachLevel as number) is 0 then -- Delta level can't be 0 (also checks string is a number)
								set validEntry to false
								exit repeat
							end if
						else
							set finalCheck to (rest of characters of eachLevel as text) as number -- Rest of string after @ must be a number
						end if
					end repeat
				on error
					set validEntry to false
				end try
			end if
 
			-- Alert and go back if invalid
 
			if validEntry is false then
 
				display dialog "\"" & levelsString & "\" is not a valid entry! Try again." with title dialogTitle with icon 0 ¬
					buttons {"OK"} default button "OK" giving up after 5
 
			else
 
				-- Final check that the levels have been interpreted correctly
 
				set pleaseConfirm to ""
				repeat with i from 1 to countLevelsArray by 3
					set eachRow to (item i of levelsArray) as number
					set eachColumn to (item (i + 1) of levelsArray) as number
					set eachLevel to item (i + 2) of levelsArray
					if eachRow is 0 then
						if eachColumn is 0 then
							set eachLine to "Master Level"
						else
							set eachLine to "Output " & eachColumn & " Level"
						end if
					else
						if eachColumn is 0 then
							set eachLine to "Input " & eachRow & " Level"
						else
							set eachLine to "Crosspoint Level: Input " & eachRow & " to Output " & eachColumn
						end if
					end if
					if eachLevel does not start with "@" then
						set eachLine to "> Add " & eachLevel & "dB to " & eachLine
					else
						set eachLine to "> Set " & eachLine & " @ " & (rest of characters of eachLevel as text) & "dB"
					end if
					set pleaseConfirm to pleaseConfirm & eachLine
					if (i + 2) is not countLevelsArray then
						set pleaseConfirm to pleaseConfirm & return
					end if
				end repeat
 
				set goBack to button returned of (display dialog "Please confirm you wish to adjust levels thus for the " & whichCuesString & ":" & ¬
					return & return & pleaseConfirm with title dialogTitle with icon 0 buttons {"Cancel", "No, no! Stop! That's not right! Go back!", "OK"} ¬
					default button "OK" cancel button "Cancel")
				if goBack is "No, no! Stop! That's not right! Go back!" then
					set validEntry to false
				end if
 
			end if
 
		end repeat
 
		-- Now, to business
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- Skip over cues that don't take levels!
				repeat with j from 1 to countLevelsArray by 3
					set eachRow to (item j of levelsArray) as number
					set eachColumn to (item (j + 1) of levelsArray) as number
					set eachLevel to item (j + 2) of levelsArray
					set currentLevel to getLevel eachCue row eachRow column eachColumn ¬
						-- This check will throw an error and exit the j repeat if the cue doesn't take levels
					if eachLevel does not start with "@" then
						set eachLevel to currentLevel + eachLevel
					else
						set eachLevel to (rest of characters of eachLevel as text) as number
					end if
					try -- This try will throw a detectable error if the next line doesn't work
						setLevel eachCue row eachRow column eachColumn db eachLevel ¬
							-- We're relying on QLab's ability to ignore spurious levels like "-200" or "+50"
						-- ###FIXME### As of 4.4.1, QLab appears to accept any negative value for Min Volume Limit and hence here too
					on error
						set ohDear to true
					end try
				end repeat
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustLevels
 
on adjustFileTarget(cuesToProcess, changeType, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		if changeType is "Change" then
			set promptHeader to "CHANGE File Target: start/end times maintained…"
		else
			set promptHeader to "SET File Target: this process will not maintain the start/end times!"
		end if
 
		set theTarget to choose file of type "public.audio" with prompt promptHeader & return & return & ¬
			"Please select the File Target to set for the " & whichCuesString & ":" without invisibles
 
		my startTheClock()
 
		set countCues to count cuesToProcess
		set checkTheFirst to true
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			if q type of eachCue is not "Group" then -- Setting File Target on a Group Cue (or cue list) affects all Audio Cues in it!
				try -- Skip over cues that don't take File Targets!
 
					if changeType is "Change" then
						set currentStart to start time of eachCue
						set currentEnd to end time of eachCue
					end if
 
					set file target of eachCue to theTarget ¬
						-- QLab doesn't appear to throw any errors even if the cue doesn't take a File Target, so no detection is possible
 
					if checkTheFirst is true then -- Check the first one worked (ie: didn't break the cue!) before going any further
						if broken of eachCue is true then -- This protects against (some) inappropriate files
							set abortAbort to true
							exit repeat
						end if
					end if
 
					if changeType is "Change" then
						set start time of eachCue to currentStart
						set end time of eachCue to currentEnd
					end if
 
				end try
				set checkTheFirst to false -- We need to check the first cue that took a target, not the first cue we tried
			end if
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustFileTarget
 
on adjustSetName(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set theName to my enterSomeText("Enter the name you wish to set for the " & whichCuesString & ¬
			" (return an empty string to reset to default names):", "", true)
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set q name of eachCue to theName
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSetName
 
on adjustSearchReplaceName(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set searchFor to my enterSomeText("Enter the search string you wish to replace in the names of the " & whichCuesString & " (not case-sensitive):", ¬
			"", false)
		set replaceWith to my enterSomeText("Enter the string with which you wish to replace all occurrences of \"" & ¬
			searchFor & "\" in the names of the " & whichCuesString & ":", "", true)
 
		my startTheClock()
 
		set countCues to count cuesToProcess
		set currentTIDs to AppleScript's text item delimiters
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			set currentName to q list name of eachCue
			set AppleScript's text item delimiters to searchFor
			set searchedName to text items of currentName
			set AppleScript's text item delimiters to replaceWith
			set theName to searchedName as text
			set AppleScript's text item delimiters to currentTIDs
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set q name of eachCue to theName
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSearchReplaceName
 
on adjustPrefixName(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set thePrefix to my enterSomeText("Enter the string you wish to add to the beginning of the names of the " & whichCuesString & ¬
			" (include a space at the end if you expect one):", "", false)
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			set currentName to q list name of eachCue
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set q name of eachCue to thePrefix & currentName
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustPrefixName
 
on adjustSuffixName(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set theSuffix to my enterSomeText("Enter the string you wish to add to the end of the names of the " & whichCuesString & ¬
			" (include a space at the beginning if you expect one):", "", false)
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			set currentName to q list name of eachCue
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set q name of eachCue to currentName & theSuffix
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSuffixName
 
on adjustSeriesName(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set validEntry to false
		set previousBaseName to ""
		set previousStartNumber to ""
		set previousIncrement to ""
		set previousPadding to ""
		repeat until validEntry is true
			set baseName to my enterSomeText("Enter the base of the name series you wish to set for the " & whichCuesString & ¬
				" (include a space at the end if you expect one):", previousBaseName, false)
			set startNumber to my enterAnInteger("Enter an integer with which to start the series:", previousStartNumber)
			set theIncrement to my enterAnInteger("Enter the increment for each step (an integer):", previousIncrement)
			set thePadding to my enterANumberWithRangeWithCustomButton("Enter the minimum number of digits – an integer between 1 & 10 " & ¬
				"(eg: entering 2 will result in the series 01, 02, etc):", previousPadding, 1, true, 10, true, true, {}, "OK")
			set previousBaseName to baseName
			set previousStartNumber to startNumber
			set previousIncrement to theIncrement
			set previousPadding to thePadding
			set counterConfirm1 to my padNumber(startNumber, thePadding)
			set pleaseConfirm1 to "> " & baseName & counterConfirm1
			set counterConfirm2 to my padNumber(startNumber + theIncrement, thePadding)
			set pleaseConfirm2 to "> " & baseName & counterConfirm2
			set counterConfirm3 to my padNumber(startNumber + 2 * theIncrement, thePadding)
			set pleaseConfirm3 to "> " & baseName & counterConfirm3
			set pleaseConfirm to pleaseConfirm1 & return & pleaseConfirm2 & return & pleaseConfirm3 & return & "> …"
			set goBack to button returned of (display dialog "Please confirm you wish to set the names as a series of this ilk for the " & whichCuesString & ¬
				":" & return & return & pleaseConfirm with title dialogTitle with icon 0 buttons {"Cancel", "No, no! Stop! That's not right! Go back!", "OK"} ¬
				default button "OK" cancel button "Cancel")
			if goBack is "OK" then
				set validEntry to true
			end if
		end repeat
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			set theCounter to startNumber + (i - 1) * theIncrement
			set theCounter to my padNumber(theCounter, thePadding)
			set theName to baseName & theCounter
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set q name of eachCue to theName
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSeriesName
 
on adjustPrefixNumber(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set thePrefix to my enterSomeText("Enter the string you wish to add to the beginning of the Cue Numbers of the " & whichCuesString & ¬
			" (include a space at the end if you expect one):" & return & return & ¬
			"(NB: if the Cue Number proposed already exists it won't be changed.)", "", false)
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			set currentNumber to q number of eachCue
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set q number of eachCue to thePrefix & currentNumber
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustPrefixNumber
 
on adjustSuffixNumber(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set theSuffix to my enterSomeText("Enter the string you wish to add to the end of the Cue Numbers of the " & whichCuesString & ¬
			" (include a space at the beginning if you expect one):" & return & return & ¬
			"(NB: if the Cue Number proposed already exists it won't be changed.)", "", false)
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			set currentNumber to q number of eachCue
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set q number of eachCue to currentNumber & theSuffix
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSuffixNumber
 
on adjustSeriesNumber(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set validEntry to false
		set previousBaseName to ""
		set previousStartNumber to ""
		set previousIncrement to ""
		set previousPadding to ""
		repeat until validEntry is true
			set baseName to my enterSomeText("Enter the base of the Cue Number series you wish to set for the " & whichCuesString & ¬
				" (include a space at the end if you expect one):", previousBaseName, false)
			set startNumber to my enterAnInteger("Enter an integer with which to start the series:", previousStartNumber)
			set theIncrement to my enterAnInteger("Enter the increment for each step (an integer):", previousIncrement)
			set thePadding to my enterANumberWithRangeWithCustomButton("Enter the minimum number of digits – an integer between 1 & 10 " & ¬
				"(eg: entering 2 will result in the series 01, 02, etc):", previousPadding, 1, true, 10, true, true, {}, "OK")
			set previousBaseName to baseName
			set previousStartNumber to startNumber
			set previousIncrement to theIncrement
			set previousPadding to thePadding
			set counterConfirm1 to my padNumber(startNumber, thePadding)
			set pleaseConfirm1 to "> " & baseName & counterConfirm1
			set counterConfirm2 to my padNumber(startNumber + theIncrement, thePadding)
			set pleaseConfirm2 to "> " & baseName & counterConfirm2
			set counterConfirm3 to my padNumber(startNumber + 2 * theIncrement, thePadding)
			set pleaseConfirm3 to "> " & baseName & counterConfirm3
			set pleaseConfirm to pleaseConfirm1 & return & pleaseConfirm2 & return & pleaseConfirm3 & return & "> …"
			set goBack to button returned of (display dialog ¬
				"Please confirm you wish to set the Cue Numbers as a series of this ilk for the " & whichCuesString & ":" & return & return & ¬
				pleaseConfirm with title dialogTitle with icon 0 buttons {"Cancel", "No, no! Stop! That's not right! Go back!", "OK"} ¬
				default button "OK" cancel button "Cancel")
			if goBack is "OK" then
				set validEntry to true
			end if
		end repeat
 
		my startTheClock()
 
		set countCues to count cuesToProcess
		set j to 0
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			set existingCueNumber to true
			repeat while existingCueNumber is true
				set theCounter to startNumber + j * theIncrement
				set theCounter to my padNumber(theCounter, thePadding)
				set theName to baseName & theCounter
				try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
					set q number of eachCue to theName
					if q number of eachCue is theName then -- Check the number has stuck; if it's already in use go round again
						set existingCueNumber to false
					else
						set j to j + 1
						set existingCueNumber to true
					end if
				on error
					set ohDear to true
				end try
			end repeat
			set j to j + 1
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSeriesNumber
 
on adjustClearNotes(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set notes of eachCue to ""
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustClearNotes
 
on adjustSetNotes(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set theNotes to my enterSomeText("Enter the Notes you wish to set for the " & whichCuesString & ":", "", false)
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set notes of eachCue to theNotes
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSetNotes
 
on adjustSearchReplaceNotes(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set searchFor to my enterSomeText("Enter the search string you wish to replace in the Notes of the " & whichCuesString & " (not case-sensitive):", "", false)
		set replaceWith to my enterSomeText("Enter the string with which wish to replace all occurrences of \"" & ¬
			searchFor & "\" in the Notes of the " & whichCuesString & ":", "", true)
 
		my startTheClock()
 
		set countCues to count cuesToProcess
		set currentTIDs to AppleScript's text item delimiters
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			set currentNotes to notes of eachCue
			set AppleScript's text item delimiters to searchFor
			set searchedNotes to text items of currentNotes
			set AppleScript's text item delimiters to replaceWith
			set theNotes to searchedNotes as text
			set AppleScript's text item delimiters to currentTIDs
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set notes of eachCue to theNotes
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSearchReplaceNotes
 
on adjustPrefixNotes(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set thePrefix to my enterSomeText("Enter the string you wish to add to the beginning of the Notes of the " & whichCuesString & ¬
			" (include a space at the end if you expect one):", "", false)
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			set currentNotes to notes of eachCue
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set notes of eachCue to thePrefix & currentNotes
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustPrefixNotes
 
on adjustSuffixNotes(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set theSuffix to my enterSomeText("Enter the string you wish to add to the end of the Notes of the " & whichCuesString & ¬
			" (include a space at the beginning if you expect one):", "", false)
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			set currentNotes to notes of eachCue
			try -- This try will throw a detectable error if the next line doesn't work (hard to think of a reason why it wouldn't though!)
				set notes of eachCue to currentNotes & theSuffix
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSuffixNotes
 
on adjustSetTime(cuesToProcess, theParameter, whichCuesString)
 
	-- subChoiceTimesParameter = {"Pre Wait", "Duration", "Post Wait"}
 
	tell application id "com.figure53.QLab.4"
 
		if theParameter is item 3 of subChoiceTimesParameter then -- Special option to set Post Waits to the same time as the Duration
			set specialCase to "Set to Duration"
		else
			set specialCase to {}
		end if
 
		set theTime to my enterATimeWithCustomButton("Enter the time you wish to set as the " & theParameter & ¬
			" for the " & whichCuesString & " (seconds or minutes:seconds):", "", specialCase)
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- This try will throw a detectable error if the appropriate line doesn't work
				if theParameter is item 1 of subChoiceTimesParameter then
					set pre wait of eachCue to theTime
				else if theParameter is item 2 of subChoiceTimesParameter then
					set duration of eachCue to theTime
				else if theParameter is item 3 of subChoiceTimesParameter then
					if theTime is specialCase then
						set theDuration to duration of eachCue
						set post wait of eachCue to theDuration
					else
						set post wait of eachCue to theTime
					end if
				end if
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSetTime
 
on adjustScaleTime(cuesToProcess, theParameter, whichCuesString)
 
	-- subChoiceTimesParameter = {"Pre Wait", "Duration", "Post Wait"}
 
	tell application id "com.figure53.QLab.4"
 
		set theMultiplicand to my enterARatio("Enter the ratio with which you wish to scale the " & theParameter & ¬
			" for the " & whichCuesString & " (eg: 1.1 will make them 10% longer):", "")
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- This try will throw a detectable error if the appropriate line doesn't work
				if theParameter is item 1 of subChoiceTimesParameter then
					set currentTime to pre wait of eachCue
					set pre wait of eachCue to currentTime * theMultiplicand
				else if theParameter is item 2 of subChoiceTimesParameter then
					set currentTime to duration of eachCue
					set duration of eachCue to currentTime * theMultiplicand
				else if theParameter is item 3 of subChoiceTimesParameter then
					set currentTime to post wait of eachCue
					set post wait of eachCue to currentTime * theMultiplicand
				end if
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustScaleTime
 
on adjustAddSubractTime(cuesToProcess, theParameter, whichCuesString)
 
	-- subChoiceTimesParameter = {"Pre Wait", "Duration", "Post Wait"}
 
	tell application id "com.figure53.QLab.4"
 
		set theAddend to my enterANumber("Enter the number of seconds you wish to add to " & theParameter & " for the " & whichCuesString & ":", "")
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- This try will throw a detectable error if the appropriate line doesn't work
				if theParameter is item 1 of subChoiceTimesParameter then
					set currentTime to pre wait of eachCue
					set pre wait of eachCue to currentTime + theAddend
				else if theParameter is item 2 of subChoiceTimesParameter then
					set currentTime to duration of eachCue
					set duration of eachCue to currentTime + theAddend
				else if theParameter is item 3 of subChoiceTimesParameter then
					set currentTime to post wait of eachCue
					set post wait of eachCue to currentTime + theAddend
				end if
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustAddSubractTime
 
on adjustSetMIDICommand(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set theParameter to my pickFromList(subChoiceMIDICommand, "Set the MIDI Command of the selected cues to:")
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- Skip over cues that don't take MIDI!
				if message type of eachCue is not voice then -- This will throw an error if eachCue isn't a MIDI Cue
					error -- This rejects MSC & SysEx cues
				end if
				try -- This try will throw a detectable error if the appropriate line doesn't work
					if theParameter is item 1 of subChoiceMIDICommand then
						set command of eachCue to note_on
					else if theParameter is item 2 of subChoiceMIDICommand then
						set command of eachCue to note_off
					else if theParameter is item 3 of subChoiceMIDICommand then
						set command of eachCue to program_change
					else if theParameter is item 4 of subChoiceMIDICommand then
						set command of eachCue to control_change
					else if theParameter is item 5 of subChoiceMIDICommand then
						set command of eachCue to key_pressure
					else if theParameter is item 6 of subChoiceMIDICommand then
						set command of eachCue to channel_pressure
					else if theParameter is item 7 of subChoiceMIDICommand then
						set command of eachCue to pitch_bend
					end if
				on error
					set ohDear to true
				end try
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSetMIDICommand
 
on adjustSetMIDI(cuesToProcess, theParameter, whichCuesString) -- This is the only one that handles "Channel"
 
	-- subChoiceMIDIParameter = {"Command", "Channel", "Byte One", "Byte Two", "Byte Combo", "End Value"}
 
	tell application id "com.figure53.QLab.4"
 
		if theParameter is item 2 of subChoiceMIDIParameter then
			set theMin to 1
			set theMax to 16
		else if theParameter is item 5 of subChoiceMIDIParameter then
			set theMin to -8192
			set theMax to 8191
		else
			set theMin to 0
			set theMax to 127
		end if
 
		set theInteger to my enterANumberWithRangeWithCustomButton("Enter the value to which you wish to set the " & theParameter & ¬
			" for the " & whichCuesString & ":", "", theMin, true, theMax, true, true, {}, "OK")
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- Skip over cues that don't take MIDI!
				if message type of eachCue is not voice then -- This will throw an error if eachCue isn't a MIDI Cue
					error -- This rejects MSC & SysEx cues
				end if
				try -- This try will throw a detectable error if the appropriate line doesn't work
					if theParameter is item 2 of subChoiceMIDIParameter then
						set channel of eachCue to theInteger
					else if theParameter is item 3 of subChoiceMIDIParameter then
						if command of eachCue is not pitch_bend then
							set byte one of eachCue to theInteger
						end if
					else if theParameter is item 4 of subChoiceMIDIParameter then
						if command of eachCue is not pitch_bend then
							set byte two of eachCue to theInteger
						end if
					else if theParameter is item 5 of subChoiceMIDIParameter then
						if command of eachCue is pitch_bend then
							set byte combo of eachCue to theInteger + 8192 -- Pitch bend of 0 in the Inspector is reported to AppleScript as 8192
						end if
					else if theParameter is item 6 of subChoiceMIDIParameter then
						if command of eachCue is not pitch_bend then
							set end value of eachCue to theInteger
						else
							set end value of eachCue to theInteger + 8192
						end if
					end if
				on error
					set ohDear to true
				end try
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSetMIDI
 
on adjustScaleMIDI(cuesToProcess, theParameter, whichCuesString)
 
	-- subChoiceMIDIParameter = {"Command", "Channel", "Byte One", "Byte Two", "Byte Combo", "End Value"}
 
	tell application id "com.figure53.QLab.4"
 
		set theMultiplicand to my enterARatio("Enter the ratio with which you wish to scale the " & theParameter & ¬
			" for the " & whichCuesString & " (eg: 1.1 will make them 10% larger):", "")
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- Skip over cues that don't take MIDI!
				if message type of eachCue is not voice then -- This will throw an error if eachCue isn't a MIDI Cue
					error -- This rejects MSC & SysEx cues
				end if
				try -- This try will throw a detectable error if the appropriate line doesn't work
					if theParameter is item 3 of subChoiceMIDIParameter then
						if command of eachCue is not pitch_bend then
							set currentValue to byte one of eachCue
							set byte one of eachCue to currentValue * theMultiplicand
						end if
					else if theParameter is item 4 of subChoiceMIDIParameter then
						if command of eachCue is not pitch_bend then
							set currentValue to byte two of eachCue
							set byte two of eachCue to currentValue * theMultiplicand
						end if
					else if theParameter is item 5 of subChoiceMIDIParameter then
						if command of eachCue is pitch_bend then
							set currentValue to (byte combo of eachCue) - 8192
							set byte combo of eachCue to currentValue * theMultiplicand + 8192
						end if
					else if theParameter is item 6 of subChoiceMIDIParameter then
						if command of eachCue is not pitch_bend then
							set currentValue to end value of eachCue
							set end value of eachCue to currentValue * theMultiplicand
						else
							set currentValue to ((end value of eachCue) - 8192)
							set end value of eachCue to (currentValue * theMultiplicand) + 8192
						end if
					end if
				on error
					set ohDear to true
				end try
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustScaleMIDI
 
on adjustAddSubractMIDI(cuesToProcess, theParameter, whichCuesString)
 
	-- subChoiceMIDIParameter = {"Command", "Channel", "Byte One", "Byte Two", "Byte Combo", "End Value"}
 
	tell application id "com.figure53.QLab.4"
 
		set theAddend to my enterAnInteger("Enter the integer you wish to add to " & theParameter & " for the " & whichCuesString & ":", "")
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- Skip over cues that don't take MIDI!
				if message type of eachCue is not voice then -- This will throw an error if eachCue isn't a MIDI Cue
					error -- This rejects MSC & SysEx cues
				end if
				try -- This try will throw a detectable error if the appropriate line doesn't work
					if theParameter is item 3 of subChoiceMIDIParameter then
						set currentValue to byte one of eachCue
						set byte one of eachCue to currentValue + theAddend
					else if theParameter is item 4 of subChoiceMIDIParameter then
						set currentValue to byte two of eachCue
						set byte two of eachCue to currentValue + theAddend
					else if theParameter is item 5 of subChoiceMIDIParameter then
						set currentValue to byte combo of eachCue
						set byte combo of eachCue to currentValue + theAddend
					else if theParameter is item 6 of subChoiceMIDIParameter then
						set currentValue to end value of eachCue
						set end value of eachCue to currentValue + theAddend
					end if
				on error
					set ohDear to true
				end try
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustAddSubractMIDI
 
on adjustSeriesMIDI(cuesToProcess, theParameter, whichCuesString)
 
	-- subChoiceMIDIParameter = {"Command", "Channel", "Byte One", "Byte Two", "Byte Combo", "End Value"}
 
	tell application id "com.figure53.QLab.4"
 
		if theParameter is item 5 of subChoiceMIDIParameter then
			set theMin to -8192
			set theMax to 8191
		else
			set theMin to 0
			set theMax to 127
		end if
 
		set startNumber to my enterANumberWithRangeWithCustomButton("Enter the value to which you wish to set the " & theParameter & ¬
			" of the first of the " & whichCuesString & ":", "", theMin, true, theMax, true, true, {}, "OK")
		set theIncrement to my enterAnInteger("Enter the increment for each step:", "")
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			set theCounter to startNumber + (i - 1) * theIncrement -- We're relying on QLab to hit a ceiling/floor for this
			try -- Skip over cues that don't take MIDI!
				if message type of eachCue is not voice then -- This will throw an error if eachCue isn't a MIDI Cue
					error -- This rejects MSC & SysEx cues
				end if
				try -- This try will throw a detectable error if the appropriate line doesn't work
					if theParameter is item 2 of subChoiceMIDIParameter then
						set channel of eachCue to theCounter
					else if theParameter is item 3 of subChoiceMIDIParameter then
						if command of eachCue is not pitch_bend then
							set byte one of eachCue to theCounter
						end if
					else if theParameter is item 4 of subChoiceMIDIParameter then
						if command of eachCue is not pitch_bend then
							set byte two of eachCue to theCounter
						end if
					else if theParameter is item 5 of subChoiceMIDIParameter then
						if command of eachCue is pitch_bend then
							set byte combo of eachCue to theCounter + 8192 -- Pitch bend of 0 in the Inspector is reported to AppleScript as 8192
						end if
					else if theParameter is item 6 of subChoiceMIDIParameter then
						if command of eachCue is not pitch_bend then
							set end value of eachCue to theCounter
						else
							set end value of eachCue to theCounter + 8192
						end if
					end if
				on error
					set ohDear to true
				end try
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSeriesMIDI
 
on adjustDeviceID(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set theParameter to my enterANumberWithRangeWithCustomButton("Enter the MSC Device ID you wish to set for the " & whichCuesString & ¬
			" (an integer from 0 to 127):", "", 0, true, 127, true, true, {}, "OK")
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			if message type of eachCue is msc then
				try -- This try will throw a detectable error if the appropriate line doesn't work (hard to think of a reason why it wouldn't though!)
					set deviceID of eachCue to theParameter
				on error
					set ohDear to true
				end try
			end if
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustDeviceID
 
on adjustAutoload(cuesToProcess, theParameter, whichCuesString)
 
	-- subChoiceAutoload = {"On", "Off"}
 
	tell application id "com.figure53.QLab.4"
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- This try will throw a detectable error if the appropriate line doesn't work (hard to think of a reason why it wouldn't though!)
				if theParameter is item 1 of subChoiceAutoload then
					set autoload of eachCue to true
				else if theParameter is item 2 of subChoiceAutoload then
					set autoload of eachCue to false
				end if
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustAutoload
 
on adjustArmed(cuesToProcess, theParameter, whichCuesString)
 
	-- subChoiceArmed = {"Armed", "Disarmed"}
 
	tell application id "com.figure53.QLab.4"
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- This try will throw a detectable error if the appropriate line doesn't work (hard to think of a reason why it wouldn't though!)
				if theParameter is item 1 of subChoiceArmed then
					set armed of eachCue to true
				else if theParameter is item 2 of subChoiceArmed then
					set armed of eachCue to false
				end if
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustArmed
 
on adjustContinueMode(cuesToProcess, theParameter, whichCuesString)
 
	-- subChoiceContinueMode = {"Do not continue", "Auto-continue", "Auto-follow"}
 
	tell application id "com.figure53.QLab.4"
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- This try will throw a detectable error if the appropriate line doesn't work (hard to think of a reason why it wouldn't though!)
				if theParameter is item 1 of subChoiceContinueMode then
					set continue mode of eachCue to do_not_continue
				else if theParameter is item 2 of subChoiceContinueMode then
					set continue mode of eachCue to auto_continue
				else if theParameter is item 3 of subChoiceContinueMode then
					set continue mode of eachCue to auto_follow
				end if
			on error
				set ohDear to true
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustContinueMode
 
on adjustMode(cuesToProcess, theParameter, whichCuesString)
 
	-- subChoiceMode = {"Timeline - Start all children simultaneously","Start first child and enter into group", "Start first child and go to next cue" ,
	(* "Start random child and go to next cue"} *)
 
	tell application id "com.figure53.QLab.4"
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			try -- Skip over cues that aren't Groups
				if mode of eachCue is not cue_list then -- Don't adjust cue lists!
					try -- This try will throw a detectable error if the appropriate line doesn't work
						if theParameter is item 1 of subChoiceMode then
							set mode of eachCue to timeline
						else if theParameter is item 2 of subChoiceMode then
							set mode of eachCue to fire_first_enter_group
						else if theParameter is item 3 of subChoiceMode then
							set mode of eachCue to fire_first_go_to_next_cue
						else if theParameter is item 4 of subChoiceMode then
							set mode of eachCue to fire_random
						end if
					on error
						set ohDear to true
					end try
				end if
			end try
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustMode
 
on adjustPatch(cuesToProcess, whichCuesString)
 
	tell application id "com.figure53.QLab.4"
 
		set theParameter to my enterANumberWithRangeWithCustomButton("Enter the patch you wish to set for the " & whichCuesString & ¬
			" (1-8, 1-16 for Network Cues):", "", 1, true, false, false, true, {}, "OK")
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			if q type of eachCue is in {"Audio", "Mic", "Video", "Network", "MIDI", "MIDI File", "Timecode"} then
				try -- This try will throw a detectable error if the appropriate line doesn't work (hard to think of a reason why it wouldn't though!)
					set patch of eachCue to theParameter
				on error
					set ohDear to true
				end try
			end if
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustPatch
 
on adjustCameraPatch(cuesToProcess, theParameter, whichCuesString)
 
	-- subChoiceCameraPatch = {1, 2, 3, 4, 5, 6, 7, 8}
 
	tell application id "com.figure53.QLab.4"
 
		my startTheClock()
 
		set countCues to count cuesToProcess
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			if q type of eachCue is "Camera" then
				try -- This try will throw a detectable error if the appropriate line doesn't work (hard to think of a reason why it wouldn't though!)
					set camera patch of eachCue to theParameter
				on error
					set ohDear to true
				end try
			end if
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustCameraPatch
 
on adjustSearchReplaceCommandText(cuesToProcess, whichCuesString, instrumentNamesONLY)
 
	tell application id "com.figure53.QLab.4"
 
		if instrumentNamesONLY is true then
			set searchFor to my enterSomeText("Enter the search string you wish to replace in the Instrument Names in the Command Text of the " & ¬
				whichCuesString & " (not case-sensitive):", "", false)
			set replaceWith to my enterSomeText("Enter the string with which wish to replace all occurrences of \"" & ¬
				searchFor & "\" in Instrument Names in the the Command Text of the " & whichCuesString & ":", "", true)
			set searchFor to searchFor & " = "
			set replaceWith to replaceWith & " = "
		else
			set searchFor to my enterSomeText("Enter the search string you wish to replace in the Command Text of the " & whichCuesString & ¬
				" (not case-sensitive):", "", false)
			set replaceWith to my enterSomeText("Enter the string with which wish to replace all occurrences of \"" & ¬
				searchFor & "\" in the Command Text of the " & whichCuesString & ":", "", true)
		end if
 
		my startTheClock()
 
		set countCues to count cuesToProcess
		set currentTIDs to AppleScript's text item delimiters
 
		repeat with i from 1 to countCues
			set eachCue to item i of cuesToProcess
			if q type of eachCue is "Light" then
				try -- This try will throw a detectable error if something doesn't work
					set currentCommandText to command text of eachCue
					if currentCommandText is not missing value then -- Skip cues that are empty
						set AppleScript's text item delimiters to searchFor
						set searchedCommandText to text items of currentCommandText
						set AppleScript's text item delimiters to replaceWith
						set theCommandText to searchedCommandText as text
						set AppleScript's text item delimiters to currentTIDs
						set command text of eachCue to theCommandText
					end if
				on error
					set ohDear to true
				end try
			end if
			if i mod userEscapeHatchInterval is 0 and (countCues - i) > userEscapeHatchInterval / 2 then -- Countdown timer (and opportunity to escape)
				my countdownTimer(i, countCues, whichCuesString)
			end if
		end repeat
 
		my finishedDialogBespoke()
 
	end tell
 
end adjustSearchReplaceCommandText
 
(* === TIME === *)
 
on makeMSS(howLong) -- [Shared subroutine]
	set howManyMinutes to howLong div 60
	set howManySeconds to howLong mod 60 div 1
	return (howManyMinutes as text) & ":" & my padNumber(howManySeconds, 2)
end makeMSS
 
on makeNiceT(howLong) -- [Shared subroutine]
	if howLong < 1 then
		return "less than a second"
	end if
	set howManyHours to howLong div 3600
	if howManyHours is 0 then
		set hourString to ""
	else if howManyHours is 1 then
		set hourString to "1 hour"
	else
		set hourString to (howManyHours as text) & " hours"
	end if
	set howManyMinutes to howLong mod 3600 div 60
	if howManyMinutes is 0 then
		set minuteString to ""
	else if howManyMinutes is 1 then
		set minuteString to "1 minute"
	else
		set minuteString to (howManyMinutes as text) & " minutes"
	end if
	set howManySeconds to howLong mod 60 div 1
	if howManySeconds is 0 then
		set secondString to ""
	else if howManySeconds is 1 then
		set secondString to "1 second"
	else
		set secondString to (howManySeconds as text) & " seconds"
	end if
	set theAmpersand to ""
	if hourString is not "" then
		if minuteString is not "" and secondString is not "" then
			set theAmpersand to ", "
		else if minuteString is not "" or secondString is not "" then
			set theAmpersand to " and "
		end if
	end if
	set theOtherAmpersand to ""
	if minuteString is not "" and secondString is not "" then
		set theOtherAmpersand to " and "
	end if
	return hourString & theAmpersand & minuteString & theOtherAmpersand & secondString
end makeNiceT
 
on makeSecondsFromM_S(howLong) -- [Shared subroutine]
	try
		set currentTIDs to AppleScript's text item delimiters
		set AppleScript's text item delimiters to ":"
		set theMinutes to first text item of howLong
		set theSeconds to rest of text items of howLong as text
		set AppleScript's text item delimiters to currentTIDs
		return theMinutes * 60 + theSeconds
	on error
		return false
	end try
end makeSecondsFromM_S
 
(* === TEXT WRANGLING === *)
 
on padNumber(theNumber, minimumDigits) -- [Shared subroutine]
	set paddedNumber to theNumber as text
	repeat while (count paddedNumber) < minimumDigits
		set paddedNumber to "0" & paddedNumber
	end repeat
	return paddedNumber
end padNumber